First, you have <IN> in three different places: the main "while" condition (which is normal), and in each of your subroutines. If it's true that the input data consists of multiple lines per data "record", it would be a good idea to document this using comments or POD in the code -- otherwise, it tends to look like a mistake.

Second, you are using a reference to a scalar variable as a hash key: $Tid{\$Tid} and this is almost certainly not what you really want. Curiously, you are sometimes using the actual scalar variable's value as the key, $Tid{$Tid} -- which is more likely what you should be doing all the time.

How about you try showing a little bit of sample data, along with what the output ought to look like given that input?

UPDATE: Oh yeah -- the reason for the warning message: You are using a new variable called "$Tid" in the final for loop for printing stuff out, but that's a new variable, so \$Tid (the reference to it) is a new memory address, and nothing has ever been assigned to the hash with that address as the key.

You can try getting rid of the backslash, but I doubt that will solve your problem completely. Here is what I recommend:

• Show a few relevant lines of your input file.
• Show the exact output you expect to get.
• Use Data::Dumper to show us the contents of your hash (Tip #4 from Basic debugging checklist).

I would not use $Tid as a global. Pass it around when you need it. Check the value of the open of the file named "file" to make sure that it worked. Instead of using "a" and "b", why not use something more descriptive like the text that was in the file, ie FIRST_NUMBER, etc?

I could make some other comments, but the most important part here is to understand the multi-dimensional hash.

#!/usr/bin/perl -w 
use strict; 
use Data::Dumper;

# hashes
my %Tids=();

#open(IN,"<file") or die "unable to open file";

while(<DATA>) {

    if(/ORIGINATION_ATTEMPT/) {
        my $Tid = findTID();
        print "$Tid,$Tids{$Tid}{'FIRST_NUMBER'},",
                    "$Tids{$Tid}{'SECOND_NUMBER'}\n";
    }
}
#close(IN);

print "============================================\n";

foreach my $Tid (keys(%Tids)) {
    print "$Tid,$Tids{$Tid}{'FIRST_NUMBER'},",
                "$Tids{$Tid}{'SECOND_NUMBER'}\n";
}

print Dumper \%Tids;


## subroutines
sub findTID {

    my $line=(<DATA>);
    if($line =~ /Tid: ([0-9a-f]{8})/) {
        my $Tid = substr($1,3,5);
 
        $Tids{$Tid}{FIRST_NUMBER} ="----------";
        $Tids{$Tid}{SECOND_NUMBER}="----------";

        findNumbers ($Tid);
        return ($Tid);
    }
}

sub findNumbers {

    my $Tid = shift;
    my $line="";

    while($line=<DATA>, $line !~ /\-{30,}/) {
  
        if($line =~ /FIRST_NUMBER\s+(\d+)\s/) {
            $Tids{$Tid}{'FIRST_NUMBER'}=$1;
        }
        if($line =~ /SECOND_NUMBER\s+(\d+)\s/) {
            $Tids{$Tid}{'SECOND_NUMBER'}=$1;
        }
    }
}

=prints ###############################
d1234,9876,9999
a4321,1234,----------
a9999,----------,3333
============================================
a9999,----------,3333
a4321,1234,----------
d1234,9876,9999
$VAR1 = {
          'a9999' => {
                       'SECOND_NUMBER' => '3333',
                       'FIRST_NUMBER' => '----------'
                     },
          'a4321' => {
                       'SECOND_NUMBER' => '----------',
                       'FIRST_NUMBER' => '1234'
                     },
          'd1234' => {
                       'SECOND_NUMBER' => '9999',
                       'FIRST_NUMBER' => '9876'
                     }
        };
=cut ######################################

__DATA__
--------ORIGINATION_ATTEMPT--------
Tid: abcd1234
FIRST_NUMBER 9876
SECOND_NUMBER 9999
---------------------------------------
--------ORIGINATION_ATTEMPT--------
Tid: defa4321
FIRST_NUMBER 1234
---------------------------------------
--------ORIGINATION_ATTEMPT--------
Tid: defa9999
SECOND_NUMBER 3333
---------------------------------------
[download]