{
    local @ARGV = ($file);
    local $^I = '.bac';
    while(<>){
        s/^\s+//;
        print;
    }
}
[download]

Thanks again wind very nicely done....I will start using it.

That is why we have subroutines:

sub pie(&@) {
  my ($cb, $file) = @_;
  rename $file, "$file~"      or die "Error backing up $file: $!";
  open my $IN,  "<", "$file~" or die "Error reading $file~: $!";
  open my $OUT, ">", $file    or die "Error writing $file: $!";

  local $_;
  while (defined( $_ = <$IN> )) {
    $cb->();
    print $OUT $_;
  }
}

pie { s/^\s+// } "myfile.txt";
[download]

perl -MMyPersonalFancyModule -e 'print qq|RTFM| x 99;'
[download]

I often build up proofs-of-concept from one-liners before I finally write them into a "real" script. invaluable to me in this process is perlrun. Perlrun has "actual" code that is equivalent to many of the commandline switches. For instance, under the section for -i[extension]:

From the shell, saying
    $ perl -p -i.orig -e "s/foo/bar/; ... "
is the same as using the program:

    #!/usr/bin/perl -pi.orig
    s/foo/bar/;
[download]

which is equivalent to

    #!/usr/bin/perl
    $extension = '.orig';
    LINE: while (<>) {
    if ($ARGV ne $oldargv) {
        if ($extension !~ /\*/) {
        $backup = $ARGV . $extension;
        }
        else {
        ($backup = $extension) =~ s/\*/$ARGV/g;
        }
        rename($ARGV, $backup);
        open(ARGVOUT, ">$ARGV");
        select(ARGVOUT);
        $oldargv = $ARGV;
    }
    s/foo/bar/;
    }
    continue {
    print;    # this prints to original filename
    }
    select(STDOUT);
[download]

except that the -i form doesn't need to compare $ARGV to $oldargv to know when the filename has changed. It does, however, use ARGVOUT for the selected filehandle. Note that STDOUT is restored as the default output filehandle after the loop.

This is a great starting place for converting your on-liner and also a great place to learn how to do it from scratch the next time.

The only other thing I would urge you to do is not to forget your strictures when you start making it a longer script. your code example:

#!/usr/bin/perl

$file="test";
$cmd="perl -pi -e s\'\/^\\s+\/\/'g $file";
print "$cmd\n";
system($cmd);
[download]

#!/usr/bin/perl

use strict;
use warnings;

$file="test";
$cmd="perl -pi -e s\'\/^\\s+\/\/'g $file";
print "$cmd\n";
system($cmd);
[download]

Having written the exact code once myself, I find it disgusting :P use B::Deparse , then transform the results

$ perl -MO=Deparse -p -i.orig -e "s/foo/bar/; ... "
BEGIN { $^I = ".orig"; }
LINE: while (defined($_ = <ARGV>)) {
    s/foo/bar/;
    die 'Unimplemented';
}
continue {
    die "-p destination: $!\n" unless print $_;
}
-e syntax OK
[download]

into a template

#!/usr/bin/perl --

use strict;
use warnings;
Main( @ARGV );
exit( 0 );
sub Main {
    RuinSomeFilesOrig(@_);
}
sub RuinSomeFilesOrig {
    local *ARGV;
    local $^I = ".orig";
    local @ARGV = @_;

    LINE: while (defined($_ = <ARGV>)) {
        s/foo/bar/;
        ...;
    }
    continue {
        die "-p destination: $!\n" unless print $_;
    }
}
[download]

then turn it into a distribution with scriptdist :D

++

---

#my sig used to say 'I humbly seek wisdom. '. Now it says:
use strict;
use warnings;
I humbly seek wisdom.

FWIW, you probably want

local @ARGV = @_; use ARGV::readonly;
[download]

see ARGV::readonly, magic-diamond <> behavior -- WHAT?!