What is the following code supposed to do?

qr/\.(rtf&ftp)$/
[download]

Where in perlre is that way of working documented?

Personally, I wouldn't try to cram the whole logic into File::Find::Rule. I would partition the work as follows:

1. Find all files
2. Remove all file names that don't end in .rtf or .ftp
3. Sort the filenames
4. For each .ftp file, look if the file following it has an identical name, except for the last four letters.

You're still very unclear, but I'm pretty sure you want the following:

For each file matching *.rtf, print its name if that directory also has similarly named file with the .ftp extension.

my @dirs = File::Find::Rule
   ->directory()
   ->in('.');

for my $dir (@dirs) {
   my @rtfs = File::Find::Rule
      ->maxdepth(1)
      ->file()
      ->in($dir);

   for my $rtf (@rtfs) {
      ( my $ftp = $rtf ) =~ s/\.rtf\z/.ftp/;
      if (-e $ftp) {
         print("$rtf\n");
      }
   }
}
[download]

Update: Condensed:

my @files = File::Find::Rule
   ->file()
   ->name('*.rtf')
   ->exec(sub{
      my $rtf = $_;
      ( my $ftp = $rtf ) =~ s/\.rtf\z/.ftp/;
      -e $ftp;
   })
   ->in('.');
[download]

Thanks for the reply ikegami.I would like to make one correction,the corresponding .ftp file not necessarily should be in the same directory,it can be in any other directory.

For example,if the directory structure is like below
c:\tests\foo.rtf
c:\tests\data\foo.ftp

if we run the script from c:\tests,it should print foo.rtf
[download]

use strict;
use warnings;

use File::Find::Rule qw( );
use File::Basename   qw( basename );

my %files;
for (
   File::Find::Rule
      ->file()
      ->name('*.rtf', '*.ftp')
      ->in('.')
) {
   my ($name, $ext) = basename($_) =~ /^(.*)\.(.*)\z/;
   ++$files{$name}{$ext};
}

for my $name (%files) {
   print("$name\n")
      if $files{$name}{rtf}
      && $files{$name}{ftp};
}
[download]

Update: Tested. Fixed.