in reply to Re^5: Failing to get current TTY's rows & columns...
in thread Failing to get current TTY's rows & columns...

Confusing docs for system ioctl & perl ioctl -- got it.

So my error check has a high level of bogosity! Details! ;-)

Regardless of the bogus error check, it still tries to extract the row,col meaning that if ioctl(STDOUT...) is valid, it should display the rows & columns.

I understand it won't work if STDOUT is redirected, but neither will opening "/dev/tty", if the program isn't running with a controlling terminal but DOES have STDOUT directed to a tty. I.e. one can always design a failure case -- but I'm more interested in why what should be a 'success' case doesn't work, namely using ioctl with 'STDOUT' when STDOUT is attached to a terminal.

Here's a simple program that should work but doesn't. Why doesn't it (I believe I've addressed the error case you raised, as well as the unpack format)? 

#!/usr/bin/perl -w
use strict;
use feature ':5.10';

{ no warnings "all";
  $SIG{__WARN__} = sub { };    #pretend "no warnings" works
  require "sys/ioctl.ph";
}

sub getwinsize (;$) {
  my $recheck=$_[0];
  my $winsize=0;
  state ($maxcols, $maxrows);

  return ($maxcols,$maxrows) if $maxcols && $maxrows && !$recheck;

  my $err = ioctl STDOUT, &TIOCGWINSZ, $winsize;
 
  unless ($err) {  
    print STDERR "ERROR: ioctl on STDOUT: $!\n";
    $err = ioctl fileno(STDOUT), &TIOCGWINSZ, $winsize;
    unless ($err) {
      print STDERR "ERROR: ioctl on fileno(STDOUT): $!\n";
    } else {
      printf STDERR "ioctl on fileno(STDOUT) worked\n";
    }
  } else {
    printf STDERR "ioctl on STDOUT worked\n";
  }

  my ($rows, $cols, $unused1, $unused2) = unpack "S!4", $winsize;

  printf STDERR "(rows=%u, cols=%u)\n", $rows//0, $cols//0;

  ($maxcols, $maxrows) = ($cols || -1, $rows || -1);
}

my ($rows,$cols) = getwinsize;

print "rows=$rows, cols=$cols\n";

# vim: ts=2: sw=2

[download]
My output: 
ERROR: ioctl on STDOUT: Bad address
ERROR: ioctl on fileno(STDOUT): Bad file descriptor
(rows=0, cols=0)
rows=-1, cols=-1

[download]

Replies are listed 'Best First'.
Application of Clarke's 3rd Law
by tchrist (Pilgrim) on Apr 17, 2011 at 05:13 UTC
    When run,the following code produces such wonders as 
    osname = Openbsd
sizeof(struct winsize) = 8
TIOCGWINSZ = 0x40087468
C       (rows,cols) = (38,126)
Perl    (rows,cols) = (38,126)

osname = Darwin
sizeof(struct winsize) = 8
TIOCGWINSZ = 0x40087468
C       (rows,cols) = (38,126)
Perl    (rows,cols) = (38,126)

osname = Solaris
sizeof(struct winsize) = 8
TIOCGWINSZ = 0x00005468
C       (rows,cols) = (38,126)
Perl    (rows,cols) = (38,126)

osname = Linux
sizeof(struct winsize) = 8
TIOCGWINSZ = 0x00005413
C       (rows,cols) = (38,126)
Perl    (rows,cols) = (38,126)

    [download]
    Interesting how you can see their genetic relationships, eh?

    Here you go. Enjoy! 

    #!/usr/bin/env perl
#
# magical winsz demo
#
# Tom Christiansen <tchrist@perl.com>
# Sat Apr 16 22:34:26 MDT 2011

use 5.10.0;
use Inline C;
no  less magic;
use strict;
use warnings;

sub TIOCGWINSZ() { TIOCGWINSZ_constant() }
use subs qw{
    tty_rows
    tty_cols
    tty_xpixels
    tty_ypixels
};

say "osname = \u$^O";
printf "sizeof(struct winsize) = %d\n", sizeof_struct_winsize();
printf "TIOCGWINSZ = %#010x\n", TIOCGWINSZ;

# first in C
my($rows, $cols) = winsizes();
say "C\t(rows,cols) = ($rows,$cols)";

# now in Perl
my $ws = "\0" x sizeof_struct_winsize();
ioctl(STDOUT, TIOCGWINSZ, $ws) || die "ioctl: $!";
($rows, $cols) = unpack(S4 => $ws);
say "Perl\t(rows,cols) = ($rows,$cols)";

exit "0 but true" || goto exit;
__END__
__C__

#include <unistd.h>
#include <stdlib.h>
#include <stdio.h>
#include <fcntl.h>
#include <sys/ioctl.h>
#include <termios.h>

int
sizeof_struct_winsize() {
    return sizeof(struct winsize);
}

int
TIOCGWINSZ_constant() {
    return TIOCGWINSZ;
}

struct winsize mywinsize;
int tty_initted = 0;

void
init_tty() {
    int ttyfd;

    if (tty_initted)
        return;

    if ((ttyfd = open("/dev/tty", O_RDWR|O_NOCTTY)) == -1)
        croak("open /dev/tty");

    if (ioctl(ttyfd, TIOCGWINSZ, &mywinsize) == -1)
        croak("ioctl TIOCGWINSZ");

    if (close(ttyfd) == -1)
        croak("close ttyfd");

    /* tty_initted = 1; */
}

void
winsizes() {
    init_tty();

    Inline_Stack_Vars;
    Inline_Stack_Reset;
#define PUSH(VALUE) Inline_Stack_Push(sv_2mortal(newSViv(VALUE)))
    PUSH(mywinsize.ws_row);
    PUSH(mywinsize.ws_col);
    PUSH(mywinsize.ws_xpixel);
    PUSH(mywinsize.ws_ypixel);
#undef PUSH
    Inline_Stack_Done;
}

int
tty_rows() {
    init_tty();
    return mywinsize.ws_row;
}

int
tty_cols() {
    init_tty();
    return mywinsize.ws_col;
}

int
tty_xpixels() {
    init_tty();
    return mywinsize.ws_xpixel;
}

int
tty_ypixels() {
    init_tty();
    return mywinsize.ws_ypixel;
}

    [download]
    There, was it good for you? :)
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom