Perllace has asked for the wisdom of the Perl Monks concerning the following question:

My need is that I will have a user who will call functions and pass various value to that. Those values would be converted as a hash and needs to be written to an xml file. For instance.. 
use Report;
$rep = Reporter->new();
my $id = "1";
my $value1 = "Some Process A";
$rep->getParameter($id,$value1);
#will do something
#will do something
my $id = "2";
my $value2 = "Some Process B";
$rep->getParameter($id,$value2);

[download]
Report will have something like 
 
Report.pm
sub getParameter
{
    my ($self, $id,$value) = @_;
    my $hash = {
        'Key' => $id,
        'Value' => $value
    };
#The idea is that I need to keep writing the values so obtained in an 
+xml format..
        
}

[download]
The xml file 
<Parameter key="1">Some Process A</Parameter> 
  <Parameter key="2">Some Process B</Parameter>

[download]
I need an XML module that will let me append these tags to the file, as and when the specific functions are called. Which XML module would do this.. and a small sample of how to use it please.. Thanks, Perllace

Replies are listed 'Best First'.
Re: Which XML module to use for this scenario?
by wind (Priest) on Apr 21, 2011 at 14:18 UTC

    If it's just a quasi XML file that you're appending values to because there is no root node, then I'd suggest you use XML::Simple.

    use XML::Simple;

use strict; 
use warnings; 

my $hash = {key => 1, content => "process a"};

print XMLout($hash, RootName => 'Parameter');

    [download]

    If it's a fully valid xml file that you'll be reading and re-writing each time, then I'd use XML::Twig.

[reply]
[d/l]
      ++ for XML::Twig. If it can't be done with Twig, I don't consider it XML. May $DEITY bless mirod.
[reply]
      Thanks wind, Please have a look at this 
      

use XML::Simple;
use strict;
use warnings;

my ($id, $value);

#group 1 paramters 
$id = "ID1";
$value = "Recording INformation";
getParameter($id, $value);
$id = "ID2";
$value = "Pausing INformation Record ";
getParameter($id, $value);
$value = "Information Loading";
getParameter($id, $value);
$value = "Information loading Complete";

#From here group 2 parameter starts
my $id = 2;
$value = "Picture loading";
getParameter($id, $value);
my $id = 3;
$value = "Picture loading complete";
getParameter($id, $value);
#Group 2 parameters end.

sub getParameter

{
    my ( $id,$value) = @_;
    my $hash = {
        'Key' => $id,
        'Value' => $value
    };

my $xml = { Parameter => [] };
push( @{ $xml->{Parameter} }
    , { key => $hash->{Key}, content => $hash->{Value} }
    );
    
    print XMLout( $xml, RootName => 'Parameter' );

}

      [download]

      Right now, the output that i get is something like 
      
 <Parameter key="ID1">Recording INformation</Parameter>
 <Parameter key="ID2">Pausing INformation Record</Parameter>
 <Parameter key="ID2">Information Loading</Parameter>
 <Parameter key="ID2">Information loading Complete</Parameter>

      [download]
      If I need something like 
      <Parameters>
- <ParameterGroup ID="Group1">
  <Parameter key="Key1">Some Value</Parameter> 
  <Parameter key="Key2">Some Value</Parameter> 
  <Parameter key="Key3">Some Value</Parameter> 
  </ParameterGroup>
- <ParameterGroup ID="Group2">
  <Parameter key="Key1">Some Value</Parameter> 
  <Parameter key="Key2">Some Value</Parameter> 
  <Parameter key="Key3">Some Value</Parameter> 
  </ParameterGroup>
  </Parameters>

      [download]
      What do I have to do? Thanks
[reply]
[d/l]
[select]

        To get XML of a specific format, work backwards. Start with xml exactly how you like it and see what type of data structure it makes:

        #!/usr/bin/perl
use Data::Dumper;
use XML::Simple;

use strict;
use warnings;

my $data = do {local $/; <DATA>};
my $xml = XMLin($data);
print Dumper($xml);

__DATA__
<Parameters>
<ParameterGroup ID="Group1">
<Parameter key="Key1">Some Value</Parameter> 
<Parameter key="Key2">Some Value</Parameter> 
<Parameter key="Key3">Some Value</Parameter> 
</ParameterGroup>
<ParameterGroup ID="Group2">
<Parameter key="Key1">Some Value</Parameter> 
<Parameter key="Key2">Some Value</Parameter> 
<Parameter key="Key3">Some Value</Parameter> 
</ParameterGroup>
</Parameters>

        [download]

        Doing this shows us our data structure. Now we just need to build it before translating to xml:

        #!/usr/bin/perl

use XML::Simple;

use strict;
use warnings;

my $xml = { ParameterGroup => [
    {
        ID => 'Group1',
        Parameter => {
            Key1 => {content => 'Some Value'},
            Key2 => {content => 'Some Value'},
            Key3 => {content => 'Some Value'},
        },
    },
    {
        ID => 'Group1',
        Parameter => {
            Key1 => {content => 'Some Value'},
            Key2 => {content => 'Some Value'},
            Key3 => {content => 'Some Value'},
        },
    },
]};

print XMLout($xml,
    RootName => 'Parameters',
    KeyAttr => 'key',
);

        [download]

        Outputs

        <Parameters>
  <ParameterGroup ID="Group1">
    <Parameter key="Key1">Some Value</Parameter>
    <Parameter key="Key2">Some Value</Parameter>
    <Parameter key="Key3">Some Value</Parameter>
  </ParameterGroup>
  <ParameterGroup ID="Group1">
    <Parameter key="Key1">Some Value</Parameter>
    <Parameter key="Key2">Some Value</Parameter>
    <Parameter key="Key3">Some Value</Parameter>
  </ParameterGroup>
</Parameters>

        [download]
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom