• Didn't you get a Can't locate object method "print" via package "twig" warning (on STDERR)? twig->print; should be $twig->print;
• I had to add root tags to your input files (again) to make them valid XML (I named them "top").
• I changed twig_handlers to twig_roots to remove desired tags from your output (see XML::Twig).
• I moved your ip/co subs outside of your parXml sub. This does not change the functionality, but I see no reason to declare a sub within a sub here.

use warnings;
use strict;
use XML::Twig;

my @array = qw(file1 file2);

foreach (@array) {
    parXML($_);
}

sub parXML {
    my $file = shift;
    #print "$file\n";
    my $twig=XML::Twig->new(twig_roots => {IP_ADDRESS => \&ip, COM=>\&
+co});
    $twig->set_pretty_print('indented');
    $twig->parsefile($file);
}

sub ip {
    my($twig, $ip)= @_;
    print "Target:".$ip->text."\n";
    $twig->print;
    $twig->purge;
}

sub co {
    my($twig, $co)= @_;
    $co->print;
    print "\n\n";
    $twig->purge;
}


__END__

Output to STDOUT:

Target:192.168.67.16
<top>
  <IP_ADDRESS>192.168.67.16</IP_ADDRESS>
</top>

  <COM>
    <DS>
      <N>1</N>
    </DS>
  </COM>

Target:192.168.67.110
<top>
  <IP_ADDRESS>192.168.67.110</IP_ADDRESS>
</top>

  <COM>
    <DS>
      <N>5</N>
    </DS>
  </COM>
[download]

On a side note, you can probably replace:

@array = `ls file* | awk '{print \$0}'`;
[download]

with:

@array = glob 'file*';
[download]