use autodie;
open my $in1, '<', $file1;
open my $in2, '<', $file2;
open my $out, '>', $file3;

for my $row ( 0..7 ) {
    my $line1 = <$in1>; 
    chomp $line1;
    my @line1 =  split / /, $line1;
    my $line2 = <$in2>; 
    chomp $line2;
    my @line2 = split / /, $line2;
 
    my @out;
    for my $col ( 0..11 ) {
         push @out, $line1[$col] - $line2[$col];
    }
    say { $out } join ' ', @out
}
[download]

Since I want to use $col to index the line component arrays, it needs to be zero based. For symmetry, $row should also be zero-based. Otherwise, I would use 1..8 and 1..12, for clarity.

use Modern::Perl;
use List::MoreUtils qw/pairwise/;
use autodie;

open my $in1, './file1.dat';
open my $in2, './file2.dat';

while (my $first = <$in1> and my $second = <$in2>) {
    my @first  = split / /, $first;
    my @second = split / /, $second;
    my @result = pairwise {$a - $b} @first, @second;
    say "@result";
}
[download]

just great! Thank you all! L

TomDLux's solution totally works, but the below code makes fewer assumptions concerning the nature of the data:

use autodie;
use List::Util qw(max);

use strict;
use warnings;

open my $in1, $file1;
open my $in2, $file2;
open my $out, '>', $file3;

while (! eof($in1) && ! eof($in2)) {
    chomp(my $line1 = <$in1>);
    chomp(my $line2 = <$in2>);
    
    my @line1 = split ' ', $line1;
    my @line2 = split ' ', $line2;

    my @out = map {$line1[$_] - $line2[$_]} (0..max($#line1,$#line2));

    print $out join(' ', @out), "\n";
}

warn "Premature end of file: $file1" if ! eof($in2);
warn "Premature end of file: $file2" if ! eof($in1);
[download]