use warnings;
use strict;
use Array::Each;

my @nums  = 1   .. 5;
my @letts = 'a' .. 'g';

my $obj = Array::Each->new(set=>[\@nums, \@letts], bound=>0, undef=>' 
+');
while (my ($n, $l) = $obj->each) {
    print "$n, $l\n";
}

__END__

1, a
2, b
3, c
4, d
5, e
 , f
 , g
[download]

Using a basic loop and List::Util. Most of the additional code is there for simple formatting.

use List::Util qw(max);

use warnings;
use strict;

my @array1 = (1..5, 10);
my @array2 = ('a'..'h');

my $length = max map {length} @array1;

for my $i (0..max($#array1, $#array2)) {
    printf "% ${length}s %s\n", $array1[$i] // '', $array2[$i] // '';
}

__END__

 1 a
 2 b
 3 c
 4 d
 5 e
10 f
   g
   h
[download]

use Modern::Perl;
use List::MoreUtils qw/each_array/;
my @first = 1 .. 10;
my @second = 'a' .. 'h';

my $ea = each_array(@first, @second);
while ( my ($first, $second) = $ea->() ) {
    say "$first <-> $second";
}
[download]

use strict;
use warnings;
my @array1=(1 .. 20);
my @array2=('a' .. 'e' );
my $max_array_length=(scalar(@array1) > scalar(@array2)) ? scalar(@arr
+ay1) : scalar(@array2);


for(my $index=0; $index<$max_array_length; $index++) {
    print $array1[$index] if $array1[$index];
    print ",";
    print $array2[$index] if $array2[$index];
    print "\n";
}
[download]

+ + (esp for the economy of solving OP's problem withOUT adding module overhead) ...but with a minor nitpick.

Consider your output, if @array1 and @array2 are swapped, making @array2 the longer of the two.

But one can make that output slightly more elegant (a matter of taste, of course; YMMV) by using the ternary again in print statements which make visual allowance for non-existent indices:

for(my $index=0; $index<$max_array_length; $index++) {
    print $array1[$index] ? $array1[$index] : '  ';
    print ", ";
    print $array2[$index] ? $array2[$index] : '-';
    print "\n";
}
[download]

Thanks. This is close to what I had been doing and it helps greatly to see it in a post ;)
I do tend to prefer to avoid adding modules if only for peace of mind that the customer can push the scripts around systems w/o fear of it breaking.

I appreciate the help :)

Instead of the ternary operator, might I recommend the "defined-or" test instead. It's more succinct and it doesn't fail on a value of '0'.

print $array1[$index] // '  ';
[download]