Just use substr to extract the proper values to sort by

my @list = map {"E$_"} (1..20);

for my $k (sort {substr($a, 1) <=> substr($b, 1)} @list) {
    print "$k ";
}
[download]

Note: If your keys don't actually all start with E, but you instead want to sort first by the alpha section and then numerically by the integer suffix, then you simply must extract the sections before sorting like so:

my @list = ("A15", "Y2", map {"E$_"} (1..20));

for my $k (
    map {$_->[0]} 
    sort {$a->[1] cmp $b->[1] || $a->[2] <=> $b->[2]} 
    map {[$_, /(\D+)(\d+)/]} 
    @list
) {
    print "$k ";
}
[download]

Excellent suggestion and one I should have thought of before. It is near the end of the week...

#!/usr/bin/perl
use strict;
use warnings;
use 5.012;
use List::Util qw/ shuffle /;

srand(1); # to get same random 'shuffle' from run to run
my @list = shuffle (qw/ Y2 A15 YABBA287 DABBA345 DOO777/, map {"E$_"} 
+(1..20));

say "UNSORTED";
say "@list";

my @sorted = map { 
                   my $strlength = unpack("C", substr($_, -1));
                   substr $_, -1 * (1 + $strlength), -1;
                 }
            sort
             map { pack "a*Na*C", /(\D+)(\d+)/, $_, length} @list;

say "SORTED";
say "@sorted";
[download]

The advantage of this sort is that it uses a simple alphabetical sort. Its is usually the fastest performing sort. The configuration here will sort any 'alpha'+'number' string, not just a single leading letter plus a number.

Update: The setup here is limited to strings of length <= 255. If the strings to be sorted are longer than that, you would have to make some changes. Also, to make the sort case insensitive, which is usually the desired outcome, the first map could be restated as:

map { pack "a*Na*C", (map {lc} /(\D+)(\d+)/), $_, length} @list;

by adding the lc operator.

Natural sort the keys

sub natural_sort {
    my $i;
    s/(\d+)/pack 'aNa*', 0, length $1, $1/eg, $_ .= ' ' . $i++ for ( m
+y @x = @_ );
    @_[ map { (split)[-1] } sort @x ];
}

print join ', ', natural_sort( map {"E$_"} (1..20) );
[download]