• Make a hash
• For each element in each list, add the list # to the hash for that element if not already on there
• For each key of the hash, if the list has more than 1 item, it's duplicated.

my %hash;
foreach my $i ( 0..$#array ) {
   foreach my $j ( @{ $array[ $i ] } ) {
      $hash{ $j } ||= [];  #need to set this if not made
      if ( ! grep { $i == $_ } @{ $hash{ $j } } ) {
         push @{ $hash{ $j } }, $i;
      }
   }
}
my @matches = grep { @{ $hash{ $_ } } > 1 } keys %hash;
[download]

Note that if you wish to exclude elements, you can simply add an "if (something) next" line in the deepest block, or do an additional grep on the @{ $array } in the second foreach block to remove elements you don't care about. But it's probably faster to look at everything, then drop what you don't need then checking every time.

This seems to work:

#!/bin/perl -w
use strict;

my @array = ([1,2,3],[5,5,6],[1,4,6]);

# nb => number of arrays in which the number is found
my %in_array;

foreach my $array (@array)
  { # the keys of %unique_for_array are the (unique) numbers in the ar
+ray
    my %unique_for_array= map { $_, 1} @$array;
    # now use those unique numbers to count
    $in_array{$_}++ foreach keys %unique_for_array;
  }

# get the duplicates
my @duplicates= grep { $in_array{$_} > 1 } keys %in_array;
print "duplicates: ", join( ', ',  @duplicates), "\n";
[download]

First, I'd do the split as "split(/\s+/,$list_of_num)". \s is 'whitespace' which includes ' ', \t (tab), \f (form feed), \r (carrage return) and, \n (newline).

If you don't need the original inner lists in the form they were read in, why not make them a hash first? this would save you a traversal of the list to make a hash of it for the uniqe-ing part.

use strict;
use Data::Dumper;

my @input = ("1 2 3",
             "5 5 6",
             "1 4 6"
            );

# outer map: take each input line
# inner map: split it on white space and return it as a hash ref
my @array = map { 
                 { map { $_ => 1 } split(/\s+/,$_) }
                } @input;

print Dumper @array;

my %unique;
for (my $i=0; $i<=$#array; $i++) {
        foreach (keys %{$array[$i]}) {
                $unique{$_}->{'pos'}->{$i} = 1;
                $unique{$_}->{'count'}++;
        }
}

my @duplicates =  grep { $unique{$_}->{'count'} > 1 } keys %unique;

foreach (@duplicates) {
        print "DUP: $_ In lists: ";

        print join(",",keys %{$unique{$_}->{'pos'}});

        print "\n";
}
[download]

/\/\averick