If you look in the documentation for readdir you will see:

If you're planning to filetest the return values out of a readdir, you'd better prepend the directory in question. Otherwise, because we didn't chdir there, it would have been testing the wrong file.

So if you change your code as follows, it will work:

$dirname = "C:/Perl/Test/"; 
opendir(DIR,$dirname);
@file1 = readdir(DIR);
foreach $file1(@file1) { 
    if (-f "$dirname$file1") { 
        print("$file1\n"); 
    } 
}
[download]

Since you're new to Perl, it's the perfect time to learn how to program with 'use strict' in mind. Try this:

use strict;
use warnings;
use autodie;


my $dirname = "C:/Perl/Test/"; 
opendir my( $dir_handle ), $dirname;
my @file1 = readdir $dir_handle;
foreach my $file1 ( @file1 ) { 
    if ( -f "$dirname$file1" ) { 
        print "$file1\n"; 
    } 
}
[download]

This is a good time to introduce grep, which can make looping tests that result in a list much simpler.

use feature qw/ say /;
use strict;
use warnings;
use autodie;

my $dirname = "C:/Perl/Test/"; 
opendir my( $dir_handle ), $dirname;

my @files = grep { -f "$dirname$_" } readdir $dir_handle;

say for @files;
[download]

say is a feature of Perl starting with 5.10. It basically just adds a "\n" to every call. my is explained best in perlsub.

readdir returns the a directory entry, not a full path. You need to do something like:

if (-f "$dirname\\$file1") {
[download]

Note that it is a bad idea to overload variable names. Your sample code uses file1 as both an array name and as the name of a scalar variable - bad, bad bad! Also, if you find yourself tacking a number on the end of a variable name then you probably want to be using an array instead, but that may be a different lesson.

There is a module File::Find which is handy for doing recursive searches of a directory tree. See File::Find. File::Find starts at the directory that you specify and for every directory and file found, it calls a subroutine that you specify. Below this is just called "wanted". There are some special variable names that apply while you are inside the wanted subroutine as shown below.

#!/usr/bin/perl -w
use strict;

use File::Find;

# within the wanted subroutine:
#
# http://perldoc.perl.org/File/Find.html
# $File::Find::dir is the current directory name,
# $_ is the current filename within that directory
# $File::Find::name is the complete pathname to the file.


my @directories_to_search = ('C:/temp');

find(\&wanted, @directories_to_search);

sub wanted
{
   print "$File::Find::name\n" if -f;
}
[download]

Your current directory is not the directory that you opened for scanning with readdir. That's why it (usually) returns false. If it returns true, it's because, by incident, a different with the same name exists in your current directory.