metaperl has asked for the wisdom of the Perl Monks concerning the following question:

I would like to use a CPAN module to clean my XML of any empty tags. Ie., given: 
<note>
  <to>
    <person>Satan</person>
  </to>
  <from via="postcard" russia="with love">moneypenny</from>
  <heading></heading>
  <body></body>
</note>

[download]
I would like to see body and heading elements stripped out and the xml with only content-laden elements in it.



The mantra of every experienced web application developer is the same: thou shalt separate business logic from display. Ironically, almost all template engines allow violation of this separation principle, which is the very impetus for HTML template engine development.

-- Terence Parr, "Enforcing Strict Model View Separation in Template Engines"

Replies are listed 'Best First'.
Re: prune xml of empty elements
by toolic (Bishop) on Jul 14, 2011 at 17:11 UTC
    XML::Twig can prune out all elements which have no text content: 
    use warnings;
use strict;
use XML::Twig;

my $str = <<EOF;
<note>
  <to>
    <person>Satan</person>
  </to>
  <from via="postcard" russia="with love">moneypenny</from>
  <heading></heading>
  <body></body>
</note> 
EOF

my $t = XML::Twig->new(
    pretty_print  => 'indented',
    twig_handlers => { _all_ => sub { $_->delete() unless $_->text() }
+ }
);
$t->parse($str);
$t->print();

__END__

<note>
  <to>
    <person>Satan</person>
  </to>
  <from russia="with love" via="postcard">moneypenny</from>
</note>

    [download]
[reply]
[d/l]
      Updated based on this clarification
      #!/usr/bin/perl --
use warnings;
use strict;
use XML::Twig;

my $str = <<'EOF';
<note>
  <to>
    <person>Satan</person>
  </to>
  <from via="postcard" russia="with love">moneypenny</from>
  <heading></heading>
  <body></body>
  <fudge a="body"></fudge>
  <fudge><a></a></fudge>
  <fudge><a body="good"></a></fudge>
</note> 
EOF

my $t = XML::Twig->new(
    pretty_print  => 'indented',
    twig_handlers => {
        _all_ => sub {
            $_->delete() unless $_->has_child or $_->has_atts
        },
    },
);
$t->parse($str);
$t->print();

__END__
<note>
  <to>
    <person>Satan</person>
  </to>
  <from russia="with love" via="postcard">moneypenny</from>
  <fudge a="body"></fudge>
  <fudge>
    <a body="good"></a>
  </fudge>
</note>

      [download]
[reply]
[d/l]
Re: prune xml of empty elements
by MidLifeXis (Monsignor) on Jul 14, 2011 at 17:48 UTC

    Is a tag with only attributes considered empty?

    --MidLifeXis

[reply]
[reply]
Re: prune xml of empty elements
by Logicus (Initiate) on Jul 14, 2011 at 20:58 UTC
    Easiest way to do this is : 
    
use Modern::Perl;

my $str = qq@

<note>
  <to>
    <person>Satan</person>
  </to>
  <from via="postcard" russia="with love">moneypenny</from>
  <heading></heading>
  <body></body>
</note>@;


$str =~ s@<(.*?)></\1>@@g;

say $str;

    [download]
    Output : 
    <note>
  <to>
    <person>Satan</person>
  </to>
  <from via="postcard" russia="with love">moneypenny</from>
  
  
</note>

    [download]
    No modules or parsing needed, just a simple one line regex.
[reply]
[d/l]
[select]
      No modules or parsing needed, just a simple one line regex.

      The only problem is that it doesn't prune every valid empty XML tag. If getting the correct result is important, use an XML parser.

[reply]
      $str =~ s@<(.*?)/>@@g;
1 while $str =~ s@<(.*?)>\s*</\1>@@g;
$str =~ s@(?<=>)\s+(?=\n)@@g;

      [download]
[reply]
[d/l]
      s@<(.*?)></\1>@@g;

      [download]

      I know one guy who writes regexes like that.

[reply]
[d/l]

Back to Seekers of Perl Wisdom