If you wish to process the file line by line, you can use the flip-flop operator. This would make it unnecessary to use explicit control flags. Here's an example:

while( <DATA> ) {
    print if /^Header2:/ .. eof;
}

__DATA__
<lsmothers@example.com>
SMTP
0<001501c4db9b$db8b2680$2d01a8c0@ryand9v889t9uc>
.X-Intermail-Unknown-MIME-Type=unparsedmessage
Header2: <headertwo@example.com
Received: from server.cluster1.example.com ([10.20.201.160])
        line 12
[download]

It seems strange to use Flip flop if you're only concerned with the initial flip. But it does work nicely. And if you're processing more than one file it can be used to catch the end of file to reset the search for the next file. The flip flop operator is discussed in the "Range Operators" section of perlop, as it's the same '..' operator.

If you prefer to slurp the file into a string and process accordingly, you can do it like this:

my $input = do { local $/ = undef; <DATA> };

if ( $input =~ /^(Header2:.+)/ms ) {
    print $1;
}
[download]

Or even...

my $input;
{
    local $/ = undef;
    $input = <DATA>;
}
print join '', ( split /^(Header2:)/m, $input, 3 )[ 1, 2 ];
[download]

The split method could be altered to avoid capturing by using a lookahead assertion as the split point, like this:

print join '', ( split /^(?=Header2:)/m, $input, 2)[1];
[download]

This method creates only two elements; the one we don't want, and the one we do. The other split method created three elements; the one we don't want, the trigger text, and the rest of what we want to keep, so for that we have to specify that we want both elements 1 and 2.

One liner versions of each of the above:

perl -ne 'print if /^Header2:/ .. eof' testdata.txt

perl -0777 -ne '/^(Header2:.+)/ms and print $1' testdata.txt

perl -0777 -pe '$_=join q//,(split /^(Header2:)/m,$_,3)[1,2]' testdata
+.txt

perl -0777 -pe '$_=join q//,(split /^(?=Header2:)/m,$_,2)[1]' testdata
+.txt
[download]

For your first example, 1 is always true, which will work fine if there is only one file in @ARGV, however you should probably use eof instead.

That's a great suggestion. I intended for it being always true, which seemed fine for simplicity's sake. But if someone is using @ARGV or the empty diamond operator, eof is the answer. Excellent. Updating now. Thanks!




Dave

$ cat sample.txt | perl -wnl -e '/\.X\-Intermail\-Unknown\-MIME\-Type\
+=unparsedmessag(e.*)/s and print $1;'
[download]

You need to slurp the entire file and you don't need to use cat:

$ perl -0777nle '/\.X-Intermail-Unknown-MIME-Type=unparsedmessage(.*)/
+s and print $1;' sample.txt
[download]

EVERYTHING I have done around this does not catch it.

Of course not, since with

perl -wnl -e
[download]

you are reading the file line by line. Try

perl -w -0777 -e
[download]

See also perlrun.

perl -ne 'print if $x; $x = $_ eq ".X-Intermail-Unknown-MIME-Type=unpa
+rsedmessage\n"' sample.txt
[download]

That is really useful. Thank you all for your solutions!