do BLOCK while COND;
[download]

is just a combination of

do BLOCK
[download]

and

EXPR while COND;
[download]

The combination is special cased to not check the while condition the first time through, but that's it.

Note that it's do that's executed repeatedly, not the block. That means the curlies aren't a loop block, so next and the like don't work.

$ perl -E'last while 1;'
Can't "last" outside a loop block at -e line 1.

$ perl -E'do { last; };'
Can't "last" outside a loop block at -e line 1.

$  perl -E'do { last; } while 1;'
Can't "last" outside a loop block at -e line 1.
[download]

Yeah, it should be "proper" loop. But it's not.

---

I usually just use an infinite loop:

for (;;) {
    my $line = <KNOME>;
    last if not defined $line;

    chomp $line;
    my ($chr, $pos) = split(/\t/, $line);
    $chr += 0;  # Numify.
    $pos += 1;  # Make 1-based

    last if $pos >= $kgArr[1];

    print OUTFILE "$chr\t$pos\n";
}
[download]

although it can be collapsed a bit:

while (defined( my $line = <KNOME> )) {
    chomp $line;
    my ($chr, $pos) = split(/\t/, $line);
    $chr += 0;  # Numify.
    $pos += 1;  # Make 1-based

    last if $pos >= $kgArr[1];

    print OUTFILE "$chr\t$pos\n";
}
[download]