First, double spacing of the code hinders the readability. Judicious application of white space is one of most important things that you can do to increase legibility of your code. Use a blank line to separate "thought units". What constitutes a "thought unit" is subjective and it takes practice to "develop a feel for it".
BTW: I really like your indenting style - perfect.

I would for example, single space all of the initial print statements and put a blank line before the i=0; statement, or perhaps like this:

print "I will calculate whatever\n",
      "you specify according to\n",
      "Ohm's law. What shall I\n",
      "calculate? Type either\n",
      "voltage, current, or\n",
      "resistance.\n";

my $i = 0;
....
[download]

The most serious flaw in the code comes here: "while($i == 0)". On a lab assignment, that certainly could be worth a full grade letter deduction (i.e. max possible grade is now a B). This would be true in Java, C, Perl or whatever.

This bad loop design error is important. I have to dig around all inside the body of your loop in order to figure out what ends the loop! The condition that ends the loop, whether it is a "for,"while","until" loop should be part of the loop condition in a very direct way. Also, you have a lot of lines between branches of the if{}elsif{}else{}, I would be thinking about subroutines or otherwise compacting things so that the whole "if" statement fits on a single page. "looks good" is another subjective measurement, but aesthetics are important. Perhaps, something like this:

#!/usr/bin/perl -w
use strict;

my $line;

while( (print "parameter to calculate?:"), 
       ($line=<STDIN>), $line !~ /^\s*q(uit)?\s*$/i)
{    
    next if $line =~ /^\s*$/; #blank line => simple re-prompt
    
    if ($line =~ /^\s*(resistance|R)\s*$/i)
    {
       print "sub to calculate resistance\n";    
    }
    elsif ($line =~ /^\s*(voltage|V)\s*$/i)
    {
       print "sub to calculate voltage\n";
    }
    elsif ($line =~ /^\s*(current|I)\s*$/i)
    {
       print "sub to calculate current\n";
    }
    else
    {
       print "illegal entry!\n";
    }   
}
[download]

Standard expected behavior for a command line program:
- if a mistake is possible, expect that user will do it (maybe unwittingly).
- allow blanks anywhere on input line (not significant anywhere -> begin, end, middle)
- blank line is not an error, just re-prompt
- if there is an error, you have to re-prompt for the user to try again...no getting to question 52 and then blowing up because the user entered "m" for "n"(no)!

The code as presented is not sufficiently tolerant of the user re-doing errors or detecting errors in the first place. This would be another full letter grade deduction.

Well written Perl code would take advantage of the language features. Some folks go crazy with super obscure "tricks". That's not necessary. A good understanding of how Perl regex works and the use of list context on the left hand side of an assignment is not considered obscure. For example, here is one regex statement to parse the amps input....not perfect, but it gets "in the ballpark".

Spaces don't matter. If some text exists past the number, then it must be either "ma" or "mA", "ba" won't work. If $flag_ma is defined, then $amps must also be defined (the division shown will work). If $amps is not defined, then the whole line failed to be valid. Very few statements, but a lot of work is done! As a relative beginner, it might take you some experimentation to figure out how it works, but it should be clear to you what it is supposed to do.

#!/usr/bin/perl -w
use strict;

my @tests = ('50 ma', '10ma', '2.3', '-.2 ma', '3.', 
             '4.0', '10ba');

foreach my $input (@tests)
{
   my ($amps, $flag_ma)= $input=~ /^\s*([-+]?\d*\.?\d+)\s*(ma|mA)?\s*$
+/;
  
   $amps /=1000    if defined $flag_ma;
   
   if (defined $amps)  
   {
       print "$amps amps\n";
   }
   else
   {
       print "$input is an illegal entry\n";
   }
}

__END__

0.05 amps
0.01 amps
2.3 amps
-0.0002 amps
3. is an illegal entry
4.0 amps
10ba is an illegal entry
[download]

prompt>    i  =  2.3
prompt> t=3
illegal syntax try again!
prompt> r =      3
prompt> v?
v=i*r
 i=2.3
 r=3
v=6.9
prompt>v=9
prompt>i?
i=v/r
  r=3
  v=9
i=3
prompt>q
good bye!
[download]

So one possible coding of an "one page Ohm's Law Calculator". There are just 3 main cases for the "if": (1) set a variable. i=2.3, (2) print a variable. v=?, and (3) wrong syntax.

#!/usr/bin/perl -w
use strict;

my %ohmsLaw;  #i,v,r

print "This is an Ohm's law program (V=I*R).\n",
      "enter statements like: \n",
      "  Enter I,V,R equation> i=2.3 or 3.2 mA or 3.2 ma\n",
      "  Enter I,V,R equation> R=4\n",
      "  Enter I,V,R equation> v=?   **asks for v to be printed**\n",
      "  prints: v=9.2   ** 9.2= (2.3 x 4) **\n",
      "basically I calculate the value that you ask for\n",
      "  based upon the previous entries for the other two\n",
      "  variables\n",
      "enter q|Q|quit to quit program\n";
      
my $line;

while( (print "Enter I,V,R equation>"), 
       ($line=<STDIN>), $line !~ /^\s*q(uit)?\s*$/i)
{    
    next if $line =~ /^\s*$/;  # simple re-prompt on blank line
    
    #
    # set an I,V,R variable...
    # 
    if (my ($vir_letter, $number, $flag_ma) = 
         $line =~ /^\s*([ivrIVR])\s*\=\s*([-+]?\d*\.?\d+)\s*(ma|mA)?\s
+*$/)
    {
       if ($vir_letter =~ /I/i)
       {
          $ohmsLaw{i}  = $number;
          $ohmsLaw{i} /= 1000 if defined $flag_ma;
       }
       $ohmsLaw{v}=$number if $vir_letter =~ /V/i;
       $ohmsLaw{r}=$number if $vir_letter =~ /R/i;  
    } 
    #
    # output a calculated I,V,R value
    #
    elsif (my ($printValue) = $line =~ /\s*(i|v|r)\s*\=\s*\?\s*$/i)
    {
       foreach my $ltr (grep{$_ ne $printValue} keys %ohmsLaw)
       {
          print "  $ltr=$ohmsLaw{$ltr}\n"; #list other values!
       }
       
       print "v=",$ohmsLaw{v}=$ohmsLaw{i}*$ohmsLaw{r},"\n" 
                  if $printValue =~ /V/i;
       print "i=",$ohmsLaw{i}=$ohmsLaw{v}/$ohmsLaw{r},"\n" 
                  if $printValue =~ /I/i;
       print "r=",$ohmsLaw{r}=$ohmsLaw{v}/$ohmsLaw{i},"\n" 
                  if $printValue =~ /R/i;
    }
    else
    {
       print "illegal syntax!\n";
    }    
}
[download]