HatTemper has asked for the wisdom of the Perl Monks concerning the following question:

Hey guys, So I'm doing a script that gets all the words from a line of a file. I'm using the following regex: @words = ($line =~ m/a-zA-Z0-9+\s/g); But I'm having trouble with the last word from the file, cuz it doesn't have a space or a new line char. Any ideas on how to improve this? UPDATE: I just did it like this: @words = ($line =~ m/a-zA-Z0-9+\s*/g);

Replies are listed 'Best First'.
Re: Regex EOF
by toolic (Bishop) on Sep 01, 2011 at 17:52 UTC
    You don't need \s 
    use warnings;
use strict;
use Data::Dumper;

my $line = 'hello world';
my @words = ($line =~ m/[a-zA-Z0-9]+/g);
print Dumper(\@words);

__END__

$VAR1 = [
          'hello',
          'world'
        ];

    [download]
    Please read: Writeup Formatting Tips
[reply]
[d/l]
[select]
Re: Regex EOF
by CountZero (Bishop) on Sep 01, 2011 at 20:23 UTC
    Such simple regexes will break on anything else but words composed of ASCII characters. Also it will add the spaces to the words.

    Try using split:

    use Modern::Perl;
use utf8;

while (<DATA>) {
    my @words = ($_ =~ m/[a-zA-Z0-9]+\s/g);
    say 'Regex  : ', join '*', @words;
    @words = ($_ =~ m/[a-zA-Z0-9]+\s*/g);
    say 'Regex *: ', join '*', @words;
    @words = split /[^\pL\pN]+/; # split on non letters + numbers
    say 'split:   ', join '*', @words;
}


__DATA__
This is a simple sentence.
This one has punctuation, indeed it has!
And  multiple  spaces  all  over  the  place  !
And nön-ascii chàraçtérs, wôw!
What about l33t sp33ch 4 u?

    [download]
    Output:
    Regex  : This *is *a *simple 
Regex *: This *is *a *simple *sentence
split:   This*is*a*simple*sentence
Regex  : This *one *has *indeed *it 
Regex *: This *one *has *punctuation*indeed *it *has
split:   This*one*has*punctuation*indeed*it*has
Regex  : And *multiple *spaces *all *over *the *place 
Regex *: And  *multiple  *spaces  *all  *over  *the  *place  
split:   And*multiple*spaces*all*over*the*place
Regex  : And *ascii 
Regex *: And *n*n*ascii *ch*ra*t*rs*w*w
split:   And*nön*ascii*chàraçtérs*wôw
Regex  : What *about *l33t *sp33ch *4 
Regex *: What *about *l33t *sp33ch *4 *u
split:   What*about*l33t*sp33ch*4*u

    [download]

    CountZero

    A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

[reply]
[d/l]
[select]
Re: Regex EOF
by Kc12349 (Monk) on Sep 01, 2011 at 21:00 UTC

    My suggestion would be to use the word boundary character, like m/\b([A-Za-z\d]+)\b/. This should match all words because word boundary includes the start of lines and end of lines in addition to spaces. Though simpler yet might be just m/\b(\w+)\b/ depending on what chars you need to match.

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom