Re: Undefining subroutines and inheritance

I discussed this with several people at YAPC last year -- I think I even talked to Larry about it. You can't localize a function, and undefing it leaves a broken stub. There were several approaches I could think of:

Create a fake class

my $x = SubClass->new;  # inherits from SuperClass

$x->method;  # calls SubClass::method
{
  local @FAKE::ISA = @{ ref($x) . "::ISA" };
  $x->FAKE::method;  # calls SuperClass::method
}
$x->method;  # calls SubClass::method
[download]

localize the glob, and restore all but the code

my $x = SubClass->new;  # inherits from SuperClass

$x->method;  # calls SubClass::method
{
  # save the glob...
  local *old = *{ ref($x) . "::method" };

  # localize the glob...
  local *{ ref($x) . "::method" };

  # and restore everything else
  ${ ref($x) . "::method" } = $old;
  @{ ref($x) . "::method" } = @old;
  %{ ref($x) . "::method" } = %old;
  # technically incomplete
  
  $x->method;  # calls SuperClass::method
}
$x->method;  # calls SubClass::method
[download]

icky eval + SUPER:: hack -- the SUPER:: doesn't work if you're not physically in the package!

my $x = SubClass->new;  # inherits from SuperClass

$x->method;  # calls SubClass::method
{
  my $pkg = ref $x;
  eval qq{
    package $pkg;
    \$x->SUPER::method;  # calls SuperClass::method
  };
}
$x->method;  # calls SubClass::method
[download]

These are gross. That's why I want to be able to say:

local &foo;
[download]

japhy -- Perl and Regex Hacker

Comment on Re: Undefining subroutines and inheritance Select or Download Code