for my $pdf (glob('*.pdf')) {
    my $txt = convert_pdf_to_text($pdf);
    next if ! interesting($txt);
    # ...
}

sub convert_pdf_to_text {
    my ($file) = @_;
    my $abs_file = rel2abs(catfile(curdir(), $file));

    ## Start Simpo PDF To Text 
    system(1, 'C:\Program Files\Simpo PDF to Text\PDF2Text.exe');

    # Locate the window
    my $wid = WaitWindow('Simpo PDF to Text', 5);
    die "Couldn't find 'Simpo PDF to Text' window" if ! defined $wid;

    ## Make sure it is on top
    SetForegroundWindow($wid);

    # Convert PDFs
    add_pdf($abs_file);
    convert();

    # Close the application
    SendKeys('%{F4}');

    my $txt_file = construct_txt_file($file);
    return '' if ! -r $txt_file;
    my $data = read_file($txt_file);
    unlink $txt_file or die $!;
    return $data;
}
[download]

You don't reap. Use waitpid($pid), the pid being returned by system 1.

Either of these will work:

1. Use a synchronous system and the start command. This will synchronously run a copy of cmd.exe to run the start command, and it starts the program asynchronously.

   As cmd.exe returns immediately and the synchronous system gathers its exit code, it avoids the accumulation of zombies and the WaitForMultipleObjects() problem:

   for ( 1 .. 100 ) {
       print "spawning job $_";
       system 'start \\Windows\\system32\\notepad.exe';
       my $wid = WaitWindow( 'Notepad', 1 );
       SetForegroundWindow( $wid );
       SendKeys( '%{F4}' );
   }
   [download]

2. Use the asynchronous system and obtain the pid of the started instance from the returned value.

   Use waitpid to gather the exit code thus avoiding the accumulation of the zombies:

   for ( 1 .. 100 ) {
       print "spawning job $_";
       my $pid = system 1, '/Windows/system32/notepad.exe';
       my $wid = WaitWindow( 'Notepad', 1 );
       SetForegroundWindow( $wid );
       SendKeys( '%{F4}' );
       waitpid $pid, 1;
   }
   [download]

Finally, 'Simpo PDF to Text' has a 'batch mode' which would be possible -- if awkward -- to drive programmically, but it might be substantially more efficient.

I guess you've already looked at command line driven alternatives?

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

BrowserUk,
Finally, 'Simpo PDF to Text' has a 'batch mode' which would be possible

That is one of the reasons I purchased it. Unfortunately, it is 'batch mode' through the UI and not command line. For my purposes, I need to make a decision after conversion before the next file that does not easily allow me to use the batch mode.

I guess you've already looked at command line driven alternatives?

Nothing I looked at did as good a job as Simpo's tool on the particular PDFs I was using. I have used a multitude of OCR tools in the past but I need to keep structure as well as text and it was the best I found for this particular data set.

Cheers - L~R