Please close your code tags properly and separate it into paragraphs as needed. Show us some sample code as well as your desired result for your sample data. The below is a good starting point

chomp(my @unsorted = (<DATA>));
my @sorted = sort { $a cmp $b } @unsorted;
say for @sorted;

__DATA__
1208782,abc
406744,def
367455,abc
283191,mps
226159,abc
197688,rxwz
137875,rxwz
115901,abc
107297,def
99213,mps
[download]

If I understand you correctly though, you just want to sum the numeric values associated with each alphanumeric code. If this is the case, you don't necessarily need to sort them. You can simple track sums into a hash.

use Data::Dump qw(pp);

chomp(my @lines = (<DATA>));
my $sums = {};
for my $line (@lines)
{
   my ($num,$let) = split ',', $line;
   $sums->{$let} += $num;
}
say pp($sums);
[download]

Thanks for the reply, The above sort is numeric .I wanted to sort the string alphabetically

1208782,abc
226159,abc
115901,abc
406744,def
107297,def
283191,mps
99213,mps
[download]

After the sort , i want to get the total of numeric values:

Total, String
1550842,abc
514041,def
.....
[download]

Thanks, Zac

If you don't mind reformatting the data slightly you can run a quick regex across the data to reverse the order of the alphanumeric and numeric data.

chomp(my @unsorted = (<DATA>));
map{ $_ =~ s/(\d+),(\w+)/$2,$1/ } @unsorted;
my @sorted = sort { $a cmp $b } @unsorted;
say for @sorted;
[download]

Or do you want to do a complex sort without reformatting? In which case you can do something like the below, which will sort without reformating.

chomp(my @unsorted = (<DATA>));
my @sorted = sort { 
   (split(',',$a))[1] cmp (split(',',$b))[1] ||
   (split(',',$a))[0] cmp (split(',',$b))[0]
   } @unsorted;
say for @sorted;
[download]

But again, if your ultimate goal is simple sums of each alphanumeric code, there is no need to sort unless you are outputting each sum as you go and purging it from memory. If holding all the sums in memory at one time is not a problem, summing into a hash should be all you need as I did in my previous example.

Another variation is to use a HoA (Hash of Array) to store the data. Then cycle through the sorted keys and either
a) print sum of array values for totals, or
b) print the array values themselves

#!/usr/bin/perl -w
use strict;
use List::Util qw(sum);

my %Alpha2Number;  #Hash of Array  def=>[406744,107297]

while (<DATA>)
{
    chomp;
    my($number, $ltrs) = split(',',$_);
    push @{$Alpha2Number{$ltrs}},$number;
}

print "Totals:\n";
foreach my $alpha (sort keys %Alpha2Number)
{
   print sum (@{$Alpha2Number{$alpha}}), ",$alpha\n";
}

print "\nSorted Data:\n";
foreach my $alpha (sort keys %Alpha2Number)
{
   print "$_,$alpha\n" for @{$Alpha2Number{$alpha}};

   #use this line if you want also to sort the numbers
   #print "$_,$alpha\n" for sort{$a<=>$b} @{$Alpha2Number{$alpha}};
}

=PRINTS
Totals:
1918297,abc
514041,def
382404,mps
335563,rxwz

Sorted Data:
1208782,abc
367455,abc
226159,abc
115901,abc
406744,def
107297,def
283191,mps
99213,mps
197688,rxwz
137875,rxwz

=cut


__DATA__
1208782,abc
406744,def
367455,abc
283191,mps
226159,abc
197688,rxwz
137875,rxwz
115901,abc
107297,def
99213,mps
[download]

No sort required. A one liner:

C:\test>type junk.dat
1208782,abc
406744,def
367455,abc
283191,mps
226159,abc
197688,rxwz
137875,rxwz
115901,abc
107297,def
99213,mps

perl -nlE"($n,$k)=split',';$h{$k}+=$n}{say$_,':',$h{$_}for keys%h" jun
+k.dat
mps:382404
def:514041
abc:1918297
rxwz:335563
[download]

But should you need the output sorted:

perl -nlE"($n,$k)=split',';$h{$k}+=$n}{say$_,':',$h{$_}for sort keys%h
+" junk.dat
abc:1918297
def:514041
mps:382404
rxwz:335563
[download]

I am not seeing the -E flag on my Perl6 distro. I downloaded the latest Rakudo Star. I supposed you're getting the latest developer build?

me@mybox:/tmp/me
$ perl6 -E 'say "bob"'
===SORRY!===
Unable to open filehandle from path '-E'
me@mybox:/tmp/me
$ perl6 -e 'say "bob"'
bob
me@mybox:/tmp/me
$ perl6 -v

This is Rakudo Perl 6, version 2011.07 built on parrot 3.6.0 0

Copyright 2008-2011, The Perl Foundation
[download]

I am not seeing the -E flag on my Perl6 distro.

Neither the code I posted nor anything in this thread mentioned Perl 6. Strictly Perl 5 only.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

#!/usr/bin/perl
use strict;
use warnings;
use 5.014;

my %data;
while (<DATA>) {
    chomp;
    my ($v, $k) = split /,/;
    $data{ $k } += $v;
}

print "$data{$_},$_\n" for sort keys %data;

__DATA__
1208782,abc
406744,def
367455,abc
283191,mps
226159,abc
197688,rxwz
137875,rxwz
115901,abc
107297,def
99213,mps
[download]

And the result is:

1918297,abc
514041,def
382404,mps
335563,rxwz
[download]

To read data from a file given as a command line argument (e.g. ./script.pl data.txt):

#!/usr/bin/perl
use strict;
use warnings;

# Read data from file
my $file = shift @ARGV;
die "Usage: $0 <data-file>\n" unless $file;
open FH, "<", $file or die "Can't open '$file': $!\n";

# Cristoforo's code (same as above)
my %data;
while (<FH>) {
    chomp;
    my ($v, $k) = split /,/;
    $data{ $k } += $v;
}

close FH;

print "$data{$_},$_\n" for sort keys %data;
[download]

Have a nice day, j