Update: Evidently this is a step too far as it produces the wrong results. It could (probably) be fixed, but it will never beat choroba's solution below.

My final offering. Combining Lotus1's sort by length with my big-string approach and this really flies, beating my previous best by an order of magnitude:

Ignore!

I slightly modified my script:

#!/usr/bin/perl

use feature 'say';
use warnings;
use strict;

my $file = 'words.txt';
open my $IN, '<', $file or die "$!";
my %words;
while (my $word = <$IN>) {
    chomp $word;
    undef $words{$word};
}

my %reported;
for my $word (keys %words) {
    my $length = length $word;
    for my $pos (0 .. $length - 1) {
        my $skip_itself = ! $pos;
        for my $len (1 .. $length - $pos - $skip_itself) {
            my $subword = substr($word, $pos, $len);
            next if exists $reported{$subword};
            next if $word eq $subword . q{s}
                 or $word eq $subword . q{'s};
            if (exists $words{$subword}) {
                say "$subword";
                undef $reported{$subword};
            }
        }
    }
}
[download]

I used english.0 from this archive as words.txt: http://downloads.sourceforge.net/wordlist/ispell-enwl-3.1.20.zip. Your script took 58s, whilest mine only 6s (on Pentium 4, 2.8 GHz). The results were different, though: your output contains the word indistinguishableness that mine does not; my list contained 911 more words than yours (e.g. you, wraps or tribe's).

Congratulations! You have the hands down winner as far as I can see.

Hash lookup beats searching every time, but the vision to invert the logic so the lookup is possible, is quite brilliant IMO.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

WOW!

I ran one of the other scripts and it took just under 24 hours to complete and I didn't get the answer I was expecting.

Your script ran in 40 seconds and gave me exactly what I was looking for!

Would you be willing to explain how this works? I get the declaration of the hash, the while loop to load the file (not sure what "undef $words{$word};" does) but the rest is pure magic!

Thank you so much for putting together this solution...I am truely blown away.

I tried to do this using T-SQL when I first encountered the problem but that was taking forever. Then I "tried" to use PERL but had way too many questions to get it to do what I needed. Your solution is awesome!

Thanks again!

your output contains the word indistinguishableness

Does your word list contain the "word": indistinguishablenessess?

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

Another tweak should improve performance again:

#! perl -slw
use strict;

my @words = do{ local @ARGV = 'words.txt'; <> };
chomp @words;

my $all = join ' ', @words;

my $start = time;

for my $i ( @words ) {

    while( $all =~ m[ ([^ ]*$i[^ ]*) ]g ) {

        my $j = $1;
        next
            if $j eq $i
            or $j eq "${i}s"
            or $j eq "${i}'s";
        print "$j contains $i";
        last;                     ## Added
    }
}

printf STDERR "Took %d seconds for %d words\n",
    time() - $start, scalar @words;
[download]