If possible, try updating your copy of Net::Whois::ARIN to the latest version (0.12). By looking at the change log and the module code, it seems that you're running into a bug that was recently fixed:

Revision history for Perl extension Net::Whois::ARIN.
 
0.12    Sat Jun 11 07:52:36 2011
        - fixed point-of-contact parsing bug
[download]

Note the changes made to the contact subroutine of the module source code (lines 393 and 394) to eliminate the possibility of storing data in $records[$n] when $n is -1.

Can anyone let me know what I'm doing wrong?

Well, a bunch of stuff really. Or at least, if not wrong, then sub-optimum. But not so much that would generate the error you describe. My best guess at the cause of your error is that one of your calls to the module is failing (no entries in a list perhaps) and that code that is called subsequently is making bad assumptions. The error itself is caused by trying to modify the last element (the -1 bit) of an empty array - the element doesn't exist and can't be modified. You are using a rather old version of Perl and possibly an old version of the module so the first thing that would be worth trying is updating to the latest version of the module.

As for the other stuff I alluded to:

1. Always use strictures (use strict; use warnings; - see The strictures, according to Seuss)
2. Use the three parameter version of open and use lexical file handles: open my $inFile, '<', $fileName or die "Can't open $fileName : $!"
3. foreach ($_) only iterates once so isn't doing anything interesting in your code
4. Generally use explicit variables rather than the default variable in general code to make the code easier to read and to avoid nasty bugs due to $_'s contents changing at unexpected times

I'd rework the code to look something like the following (untested):

#!/usr/bin/perl
use strict;
use warnings;

use Net::Whois::ARIN;

my $file = "file_containing_IPs.txt";

open my $inFile, '<', $file or die "Unable to open $file: $!\n";

my $w = Net::Whois::ARIN->new (
    host    => 'whois.arin.net',
    port    => 43,
    timeout => 30,
) or die "Can't access server: $!\n";

while (defined (my $line = <$inFile>)) {
    chomp $line;
    next if !length $line;

    for my $net ($w->network ($line)) {
        printf "CIDR: %s\tNetName: %s\tNetHandle: %s\n",
            $net->CIDR, $net->NetName, $net->NetHandle;
    }
}

close $inFile;
[download]

I don't have the module installed, but what happens if you remove the (pointless) outer for loop?:

while(<LIST>) {
    chomp;
    my @output = $w->network($_);
    foreach my $net(@output) {
        printf( "CIDR: %s\tNetName: %s\tNetHandle: %s\n",
            $net->CIDR, $net->NetName, $net->NetHandle,
        );
    }
}
[download]

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;    # this makes error messages nicer.
[download]

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;    # this makes error messages nicer.
use Net::Whois::ARIN;

my $file="file_containing_IPs.txt";

open(LIST,$file) or die "Unable to open file $file:$!\n";

my $w = Net::Whois::ARIN->new(
  host    => 'whois.arin.net',
  port    => 43,
  timeout => 30,
);

while(<LIST>) {
  foreach ($_) {
    chomp;
    if(defined $_ && $_) {
      my @output = $w->network($_);
      foreach my $net (@output) {
        printf(
          "CIDR: %s\tNetName: %s\tNetHandle: %s\n",
          $net->CIDR,
          $net->NetName,
          $net->NetHandle,
        );
      }
    }
  }
}

close(LIST);
[download]