Assuming that you've already used CGI.pm and declared the hash. And also that the text field is called hashdata...

foreach (split /,\s*/, param('hashdata')) {
  my ($k, $v) = split(/=>/);
  $hash{$k} = $v;
}
[download]

If you know the hash is going to be empty at the start, then it gets a bit simpler...

%hash = map { split /=>/ } 
        split /,\s*/, param('hashdata');
[download]

You might also want to add a little data filtration on the keys and values to at least strip leading and trailing whitespace otherwise "a=>4" will generate a different key to say " a =>4". Something like:

foreach (split /,\s*/, param('hashdata')) {
   my ($k, $v) = split(/=>/);
   whitespace(\$k,\$v);
   $hash{$k} = $v;
}


sub whitespace {
   while (my $ref = shift){
      $$ref =~ s/^\s+|\s+$//g
   }
}
[download]

We pass the sub references to the variables so we can change them in the sub and not bother having to return the changed values and assign them.

cheers

tachyon

chromatic points out that split(/\s*=>\s*/) is is a shorter and more efficient solution to the whitespace problem:

foreach (split /,\s*/, param('hashdata')) {
     my ($k, $v) = split(/\s*=>\s*/);
     $hash{$k} = $v;
  }
[download]

I have to agree :-(

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print