until ($COND) {
    some($stuff);
    if ($THIS) {
        do($that);
    }
    else {
        do($anything);
    }
}
[download]

Got it! I had been moving things all over the place tyring to get it to work. It was the way I had setup the block. Thanks for your clearer explanation of the until construct.

anylou... this works.

#!/usr/bin/perl -w

use strict ;
use diagnostics;
use LWP::Simple ;

print "This will get the time from an NIST clock 5 times
and then ask you if you want to continue.  Use 'y'
to continue and any other key to stop:\n\n" ;

my $answer ;
my $quit = 0 ;

until ($quit) {
     getprint "http://132.163.4.101:13" ;
     getprint "http://132.163.4.101:13" ;
     getprint "http://132.163.4.101:13" ;
     getprint "http://132.163.4.101:13" ;
     getprint "http://132.163.4.101:13" ;
     print "\n\nDo you  want to continue?  " ;
          
     $answer = <STDIN> ;
     chomp $answer ;
     
     if ($answer eq 'y') {     
     print "OK\n" ;
          } else { 
          $quit = 1 ;
          }
}

print "Good-bye!\n\n" ;
[download]



--
lmoran@wtsgSPAM.com
print "\x{263a}"

You may still want to look at how you are using your braces relative to your indenting structure (see the addition to my note and the other comments). A good text editor like emacs (among others) will do a lot of this work for you.

Probably you see it yourself if I modify the layout of your code:

my $answer ;
my $quit = 0 ;

until ($quit) {
  getprint("http://132.163.4.101:13") ;
  getprint("http://132.163.4.101:13") ;
  getprint("http://132.163.4.101:13") ;
  getprint("http://132.163.4.101:13") ;
  getprint("http://132.163.4.101:13") ;
  print "Do you  want to continue?  " ;
  $answer = <STDIN> ;
  chomp $answer ;
}

if ($answer ne 'y') {
  print "OK\n" ;
} else { 
  $quit = 1 ;
  die "OK!\n\n" ;
}

print "Good-bye!\n\n" ;
[download]

-- Hofmator

Consider your code with some indentation added

#!/usr/bin/perl -w

use strict ;
use diagnostics;
use LWP::Simple ;

print "This will get the time from an NIST clock 5 times
and then ask you if you want to continue.  Use 'y'
to continue and any other key to stop:\n\n" ;

my $answer ;
my $quit = 0 ;

until ($quit) {
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     print "Do you  want to continue?  " ;
     $answer = <STDIN> ;
     chomp $answer ;
} 
if ($answer ne 'y') {     
    print "OK\n" ;
} else { 
    $quit = 1 ;
    die "OK!\n\n" ;
}
print "Good-bye!\n\n" ;
[download]

I have indented your code as I normally would. The problem as you can see is that you test the conditional outside the until loop. No test == No exit. You could also simplify a lot to this:

#!/usr/bin/perl -w

use strict ;
use diagnostics;
use LWP::Simple ;

print "This will get the time from an NIST clock 5 times
and then ask you if you want to continue.  Use 'y'
to continue and any other key to stop:\n\n" ;

my $answer = 'y' ;

until ($answer !~ /^y$/i ) {
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     getprint("http://132.163.4.101:13") ;
     print "Do you  want to continue?  " ;
     $answer = <STDIN>;
     chomp $answer;
} 

print "Good-bye!\n\n" ;
[download]

I like this structure a lot more as it is simple and skips extra vars. Less code == Less bugs. By using a regex match we allow a little more flexibility with lower case or capital 'Y' acceptable.

cheers

tachyon

s&&rsenoyhcatreve&&&s&n\w+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

On a completely different track (since everybody else answered this question)... looking at the following:

  if ($answer ne 'y') {     
       print "OK\n" ;
  } else { 
       $quit = 1 ;
       die "OK!\n\n" ;
  }
[download]

Why not try the following:

  $quit = ($answer !~ m/^y/i);
[download]

This way if somebody enteres "y" or "Y" or "Yes" etc. it will work (never underestimate what users will type in... even yourself).

The die is not necessary since the until loop is fixed. You're breaking program structure by forcing an exit with die.

You can also use what's called a naked block, to do what you want:

#!/usr/bin/perl -w

use strict ;
use LWP::Simple qw(getprint);

use constant NIST_SERVER => 'http://132.163.4.101:13';

print <<HERE;
This will get the time from an NIST clock 5 times
and then ask you if you want to continue.  Use 'y'
to continue and any other key to stop:

HERE

{
  getprint(NIST_SERVER) for 1..5;

  print 'Do you want to continue? [yn]: ';
  chomp(my $answer = <STDIN>);
  redo if lc($answer) eq 'y';
}

print "Good-bye!\n\n";
[download]