#!/usr/bin/perl
use strict;
use Tie::File;
use List::Util qw/shuffle/;
[download]

You should also include the warnings pragma (it would have warned you about one of the lines of your program.)

#!/usr/bin/perl
use warnings;
use strict;
use Tie::File;
use List::Util qw/shuffle/;
[download]

my $line;
my $i=0;
my @array;
my $count=0;
my $alphaFile = 'alphabetFile.txt';
my $numberFile = 'numberFile.txt';
my $fileCounter = 'counter.txt';
my $tempFile = 'temp.txt';

open(FILECOUNTER,$fileCounter);
$count = <FILECOUNTER>;
chomp($count);
[download]

Why are these lines in file scope?    They should be inside the subroutine.    You should also verify that open worked correctly.

&readfile();
[download]

There is no need to prepend an ampersand when using subroutine calls and it may cause unwanted side effects.

    tie @array, 'Tie::File', $numberFile || die("failed to open $numbe
+rFile");;
[download]

You should declare @array here where you first use it instead of at file scope.

You are using the high precedence || operator which means that you are testing the boolean value of $numberFile NOT the success or failure of tie.

    tie my @array, 'Tie::File', $numberFile or die "failed to open $nu
+mberFile";
[download]

    if (-e $tempFile) {
        open(TEMPFILE,"+<$tempFile") || die("failed to open $tempFile"
+);
[download]

There is no need to stat the file first, just let open do its job:

    if ( open TEMPFILE, '+<', $tempFile ) {
[download]

    my $counter=0;
[download]

You never use this variable anywhere??

    tell(TEMPFILE);
[download]

You are using tell in void context so this line is superfluous.    (The warnings pragma would have warned you of this.)

    while ($line = <CHARFILE>) {
[download]

You should declare $line here where you first use it instead of at file scope:

    while ( my $line = <CHARFILE> ) {
[download]

            if ("$line $array[$i]") {
[download]

This test is superfluous because the string "$line $array[$i]" is ALWAYS true.

                foreach ( $line ) {
[download]

You are looping over a list with one element.    The foreach loop aliases $line to $_ but you are not using $_ inside the loop so it is superfluous.

                        print shuffle $array[$i] . "\n";
[download]

shuffle works on a list and returns a shuffled list but you are only passing shuffle a single element, the string "$array[$i]\n", so there is nothing really for shuffle to do, except return that one element.

                        print "\n" . $line . " " . rand "$array[$i]" .
+ "\n";
[download]

You have three problems there: 1) rand works with numbers but you are copying the contents of $array[$i] to a string, so perl has to convert that string to a number for rand to work, and: 2) because of the high precedence of the concatenation operator you are actually passing rand the string "$array[$i]\n" which means that: 3) the newline is not printed out as you may have expected.

That will work correctly if you use the comma operator instead:

                        print "\n", $line, " ", rand $array[ $i ], "\n
+";
[download]

You should also include the $! in your error messages when using open so you know why it failed.

There is no need to prepend an ampersand when using subroutine calls and it may cause unwanted side effects.

FUD much? :)

Just testing in Production. Sorry, it shouldn't have let me post this.

If you maintain the history in a YAML file then you can do something like:

#!/usr/bin/perl
use strict;
use YAML qw();

my $kGenLines = 3;
my $history   = eval {YAML::LoadFile('history.yaml')} || {};

# Adjust history
$history->{$_} && --$history->{$_} for keys %$history;

#generate lines
my @alphas = 'A' .. 'M';
my @nums   = 1 .. 5;

LINES: for (1 .. $kGenLines) {
    my @aPool = @alphas;
    my $pair;

    while (@aPool) {
        my @nPool = @nums;
        my $tryAlpha = splice @aPool, rand(@aPool), 1;

        while (@nPool) {
            my $tryNum = splice @nPool, rand(@nPool), 1;

            next if $history->{"$tryAlpha|$tryNum"};

            @alphas = grep {$_ ne $tryAlpha} @alphas;
            @nPool = grep {$_ != $tryNum} @nPool;
            print "$tryAlpha $tryNum\n";
            $history->{"$tryAlpha|$tryNum"} = 5;

            next LINES;
        }
        
        @alphas = grep {$_ ne $tryAlpha} @alphas;
    }
}

YAML::DumpFile('history.yaml', $history);
[download]