Hi. Is there a way to change all tags and attributes in XML to lower case?

Sure, here is a start

#!/usr/bin/perl --
use strict; use warnings;
use XML::Twig;
my $str = <<'EOF';
<NoTe>
  <To>
    <Person>Satan</Person>
  </To>
  <Beef><SaUsAGe>is Tasty</SaUsAGe></Beef>
</NoTe> 
EOF

{
    my $t = XML::Twig->new(
        pretty_print  => 'indented',
        force_end_tag_handlers_usage => 1,
        start_tag_handlers => { _all_ =>  sub { $_->set_tag( lc $_->ta
+g );  return }, },
        end_tag_handlers => { _all_ =>  sub { $_->set_tag( lc $_->tag 
+); return }, },
    );
    $t->parse($str);
    $t->flush();
}
__END__
[download]

(Faced XPath feature being case-insensitive)

Why is this a problem?

Nice! One of the few cases where it makes sense to use force_end_tag_handlers_usage, Bravo!

I don't think you need the end_tag_handlers handler though, the start one should be enough. You could also flush at the end of the handler to save memory, if that's an issue (untested).

Yup, start_tag_handlers is enough, but the flushing has to be done from end_tag_handler

#!/usr/bin/perl --
use strict; use warnings;
use XML::Twig;
my $str = <<'EOF';
<NoTe KunG="FoO" ChOp="SuEy">
  <To KunG="FoO">
    <Person KunG="FoO">Satan</Person>
  </To>
  <Beef KunG="FoO"><SaUsAGe KunG="FoO">is Tasty</SaUsAGe></Beef>
</NoTe> 
EOF

{
    my $t = XML::Twig->new(
        pretty_print  => 'indented',
        force_end_tag_handlers_usage => 1,
        start_tag_handlers => {
            _all_ =>  sub {
                $_->set_tag( lc $_->tag );
                if(  $_->has_atts ){
                    my $atts = $_->atts ;
                    $_->set_atts ({
                        map {
                            lc( $_ ) => $atts->{$_}
                        } keys %{ $atts }
                    });
                }
                return
            },
        },
        end_tag_handlers => { _all_ =>  sub { $_->flush; return }, },
    );
    $t->parse($str);
    $t->flush();
}
__END__
<note chop="SuEy" kung="FoO">
  <to kung="FoO">
    <person kung="FoO">Satan</person>
  </to>
  <beef kung="FoO">
    <sausage kung="FoO">is Tasty</sausage>
  </beef>
</note>
[download]

I don't think you need the end_tag_handlers handler though, the start one should be enough. You could also flush at the end of the handler to save memory, if that's an issue (untested).

Flushing in start_tag handler doubles the output  <note chop="SuEy" kung="FoO"></note> but end_tag_handlers => { _all_ doesn't get called at all

so nothing gets flushed until the whole tree is parsed

Is this by design of end_tag_handlers?

The problem is it's 10-50mb per file, and there are CDATA sections also. And i need to transform the xml very fast.

lower-casing xml tags and attributes won't be a significant speedup

I usually use XML::XSH2 for XML manipulation. To lowercase all element and attribute names, you can use:

rename xsh:lc(name(.)) (//* | //@*)
[download]