my %gp = (
  ...
  Gi => \@gi, # an array ref
  Gt => \@gt,
);
[download]

In your while loop you will first need to test if it is an array ref and, if so, dereference it. Something like

  ...
  $j = $gp{$i};
  my @values;
  if (ref $j eq 'ARRAY'){
    @values = @{$gp{$i}};
  }
  else {
    @values = ($j);
  }
  for $val (@values){
  ...
[download]

If your code is very representative, it seems you can do away with your hash and arrays, and do something like this where you first assign $j:

   ($j=$i)    =~ s/G(.+)/Galpha-$1/;
   my @values = ($j =~ /(Galpha-[it])/  
                    ? map{$1.$_}1..3 
                    : ($j)
                 );
[download]

Also, read up on modifiers in perlre. You have this:

   if ($_=~/^.*\t.*\t(.*)\t.*\t.*/mgi)
[download]

All the modifiers are unnecessary:

• m, because you are matching against a single line;
• g, because you match the (one) beginning of the line;
• i, because you are matching .*, i.e., in any case

Update: Clearly, I don't have a clue what your data looks like, but I'm thinking something like this:

use strict;
use warnings;

while (<DATA>){
   chomp;
   next unless  my $i = (split/\t/,$_)[2];

   my $f =  $_;
      $i =~ s/ //g;

  (my $j = $i)  =~ s/G(.+)/Galpha-$1/;

   my @values = ($j =~ /(Galpha-[it])/ 
                    ? map{$1.$_}1..3 
                    : ($j)
                );

   for my $val (@values) {
      my $k =  $f;
      $k    =~ s/$i/$val/g;
      print "$k\n";
   }
}
__DATA__
biologist    xargon    Gi    question
perl    monks    G11    answer?
# prints
biologist       xargon  Galpha-i1       question
biologist       xargon  Galpha-i2       question
biologist       xargon  Galpha-i3       question
perl    monks   Galpha-11       answer?
[download]

++wfsp. For uniformity, I would store *every* value of %gp as an arrayref, rather than need conditional logic on every use of a value.

Here is my quick refactor, with ++hbm's test data (padded to 5 columns):

use strict;
use warnings;
my %gp = (
    G11  => [qw( Galpha-11  )],
    G12  => [qw( Galpha-12  )],
    G13  => [qw( Galpha-13  )],
    G14  => [qw( Galpha-14  )],
    G15  => [qw( Galpha-15  )],
    G16  => [qw( Galpha-16  )],
    Gs   => [qw( Galpha-s   )],
    Gz   => [qw( Galpha-z   )],
    Golf => [qw( Galpha-olf )],
    Go   => [qw( Galpha-o   )],
    Gq   => [qw( Galpha-q   )],

    Gi   => [qw( Galpha-i1 Galpha-i2 Galpha-i3 )],
    Gt   => [qw( Galpha-t1 Galpha-t2 Galpha-t3 )],
);

my $re = qr{
  \A
     ( [^\t]* \t [^\t]* )
  \t ( [^\t]*           )
  \t ( [^\t]* \t     .* )
  \z
}msx;

LINE:
while ( my $line = <DATA> ) {
    chomp $line;

    my ( $col_1_2, $col_3, $col_rest ) = ( $line =~ /$re/ ) or do {
        warn "Line $. did not match: '$line'";
        next LINE;
    };

    $col_3 =~ tr{ }{}d;

    my $aref = $gp{$col_3} or do {
        # No replacement needed? Is line still wanted?
        warn "Did not find '$col_3' in %gp";
        print $line, "\n";
        next LINE;
    };

    for my $val ( @{ $aref } ) {
        print join( "\t", $col_1_2, $val, $col_rest ), "\n";
    }
}
__DATA__
biologist    xargon    Gi    question    col5
perl    monks    G11    answer?    col5
[download]

both make @gi interpolate
the first one is

Gi   =>  $gi[0],
$gi[1] => $gi[2],
[download]

%gp = ( Gi => [qw[Galpha-i1 Galpha-i2 Galpha-i3]],
      );
print $gp{Gi}[1];
[download]

update:
This is now bugging me. :-) I can't see what the for loop is doing. I really need to see the data. Give me the data. :-)

If a line in your input is:

then what do you want your output to be? Is the "Gi" supposed to be replaced with one of the three items in your @gi array, or all three at once, or should the line be printed three times, once for each value? My guess based on your code is that it should become three lines.

yes, sorry about that.As you correctly said, i wanted to replace Gi with every item in the corresponding array and then print it once with each changed value (aka 3 lines)

Problem:
I have a tab separated csv file. If the term in column 3 is in my translation table, instead of printing that line I want to print a new CSV line using each of the equivalent translation term(s). If a CSV line has less than 5 columns or the term cannot be translated - no processing is done and line is not printed (not sure about this). Below I have used | as the separator instead of \t so that the data is easier to see and work with...

If my understanding of what you want is wrong, then please correct me and we'll go from there.

The best data structure appears to be a HashOfArray (HoA). This eliminates the need for a special case of one term vs more than one term. ++Util Using a HoA in this translation sense is common and is a reasonable approach.

I see no need for any kind of regex at all. The right tool here appears to be split, not regex. Check if the number of columns is enough and if so, then check if the term in column 3 can be translated. If both of these are true, then just print one line per translation term.

If you want case insensitive comparisons, then convert the translation keys to all one case (upper or lower) and also case the column 3 term the same way.

#!/usr/bin/perl -w
use strict;

my @gi=("Galpha-i1", "Galpha-i2", "Galpha-i3");
my @gt=("Galpha-t1", "Galpha-t2", "Galpha-t3");

my %gp = (
    G11  => [qw( Galpha-11  )],
    G12  => [qw( Galpha-12  )],
    G13  => [qw( Galpha-13  )],
    G14  => [qw( Galpha-14  )],
    G15  => [qw( Galpha-15  )],
    G16  => [qw( Galpha-16  )],
    Gs   => [qw( Galpha-s   )],
    Gz   => [qw( Galpha-z   )],
    Golf => [qw( Galpha-olf )],
    Go   => [qw( Galpha-o   )],
    Gq   => [qw( Galpha-q   )],
    Gi   => [@gi],
    Gt   => [@gt],
);

while (<DATA>)
{
    chomp;
    my @columns = split(/\|/, $_);

    next if ( @columns <5 or !exists $gp{$columns[2]});
   
    foreach my $replacement (@{$gp{$columns[2]}})
    {
        print "$columns[0]|$columns[1]|$replacement|",
              join("|",@columns[3..@columns-1]),"\n";
    }
}
=prints
biologist|xargon|Galpha-i1|question|col5
biologist|xargon|Galpha-i2|question|col5
biologist|xargon|Galpha-i3|question|col5
bobby|jane|Galpha-11|somewthing|col5|col6
=cut

__DATA__
biologist|xargon|Gi|question|col5
bobby|jane|G11|somewthing|col5|col6
perl|monks|G11|too_short
[download]

Update:

Gq   => [qw( Galpha-q   )],
Gi   => [@gi],
[download]