sub func { return (0, 1, 2) }

if (1 and do { ($result) = func($param); $result }) {
   print "1\n";
} else {
   print "0\n";
}

if (1 and ($result) = func($param)) {
   print "1\n";
} else {
   print "0\n";
}
[download]

0
1
[download]

($result) = func($param)
[download]

is a list assignment, and it happens to be in scalar context. List assignment in scalar context returns the number of elements returned by its RHS. (See Mini-Tutorial: Scalar vs List Assignment Operator.)

If func returns three values, the second snippet is equivalent to

if (... and do { ($result) = func($param); 3 })
[download]

which is different than

if (... and do { ($result) = func($param); $result })
[download]

As shown above, the difference will matter when func returns more than one value and the first is false.

You can avoid the do using a list slice.

if (... and $result = (func($param))[0])
[download]

Scalar assignment returns its LHS.

I can't think of any excuse for either form. There is a balance between terseness and obfuscation. Both those statements are rather more toward the obfuscation side of the balance than toward the useful terseness side (at least in my view - YMMV).

The only reason I imagine for the first form is when autogenerating code. If a code fragment consists of more than a simple expression, the do-block will always convert that fragment to an expression.

Update: Also see ikegami's advice about list context below!

if (1 and ($result = (func($param))[0])) {
   print "1\n";
} else {
   print "0\n";
}
print "$result\n";

sub func { return (0, 1, 2); }
[download]

Prints two 0's, which seems to be what is wanted here - and with syntax that makes more direct sense than form #1 (at least in my opinion).