Here's a slight variation. This one prints the line before and after the line(s) that match (the amount of lines is controlled by the variable $range). It uses a circular buffer, but all the functionality of dealing with circularity is hidden inside a tie mechanism.

#!/opt/perl/bin/perl

use strict;
use warnings;

my $file   = "/usr/dict/words";  
my $word   = "perl";
my $range  = 1;     # -$range .. $range
my $size   = 2 * $range + 1;

sub TIEARRAY  {bless [("") x $_ [1]] => $_ [0]}
sub STORE     {${$_ [0]} [$_ [1] % @{$_ [0]}] = $_ [2]}
sub FETCH     {${$_ [0]} [$_ [1] % @{$_ [0]}]}
sub FETCHSIZE {scalar @{$_[0]}}
sub STORESIZE {die}
 
tie  my @buffer => 'main', $size;
open my $fh => $file or die "Failed to open $file: $!";
 
while (<$fh>) {
    $buffer [$.] = $_;
    if ($buffer [$. - $range] =~ /$word/) {
        print @buffer [$. - $size + 1 .. $.];
    }
}
 
# Borderline, matches at the end:
for my $line ($. - $range + 1 .. $.) {
    print @buffer [$line - $range .. $.] if $buffer [$line] =~ /$word/
+;   
}


__END__
[download]

-- Abigail