I wouldn't use splice at all. Instead I'd merge the two arrays:

#!/usr/bin/perl
use strict;
use warnings;


my @first  = qw(Can unlock secret);
my @second = qw(you the code?);
my @interleave;

push @interleave, grep {$_} (shift @first), shift @second
    while @first || @second;

print "@interleave";
[download]

Although you could use splice to do an "in place' merge:

#!/usr/bin/perl
use strict;
use warnings;

my @first  = qw(Can unlock secret);
my @second = qw(you the code?);

splice @first, @second, 0, pop @second while @second;

print "@first";
[download]

or avoiding destroying the contents of @second:

...
splice @first, $_, 0, $second[$_ - 1] for reverse 1 .. @second;

print "@first";
[download]

or using splice to populate a new array:

my @new;

splice @new, 0, 0, $first[$_], $second[$_] for reverse 0 .. $#second;
print "@new";
[download]

Note that a few of these do stuff backwards to avoid having to account for elements that have been inserted into the target array.

Now, to answer your actual question. First lets add diagnostics a little differently to your existing code:

#!/usr/bin/perl
use strict;
use warnings;


my @first = qw(Can unlock secret);
my @second = qw(you the code?);

dumpArrays('start', \@first, \@second);

splice(@first, 1, 0, @second[0,-2]);
dumpArrays('first', \@first, \@second);

my @newArray = @first;

splice(@newArray, 5,0,@second[0,2]);
dumpArrays('na', \@first, \@second, \@newArray);

my @newArray1 = @newArray;

splice(@newArray1, 2,1);
dumpArrays('na1', \@first, \@second, \@newArray1);

my @newArray2 = @newArray1;

splice(@newArray2, 4,1);
dumpArrays('na2', \@first, \@second, \@newArray2);

my @newArray3 = @newArray2;

splice(@newArray3,3,0, @second[1,1]);
dumpArrays('na3', \@first, \@second, \@newArray3);


sub dumpArrays {
    my ($msg, @arrays) = @_;

    printf "%-10s %s\n", $msg, join '|', map {"@$_"} @arrays;
}
[download]

Prints:

start      Can unlock secret|you the code?
first      Can you the unlock secret|you the code?
na         Can you the unlock secret|you the code?|Can you the unlock 
+secret you code?
na1        Can you the unlock secret|you the code?|Can you unlock secr
+et you code?
na2        Can you the unlock secret|you the code?|Can you unlock secr
+et code?
na3        Can you the unlock secret|you the code?|Can you unlock the 
+the secret code?
[download]

Note that the error doesn't happen until the very last step. In that step you splice(@newArray3,3,0, @second[1,1]);. @second[1,1] which inserts two copies of the word 'the'. You just needed $second[1] there.

use List::MoreUtils qw( mesh );
my @first  = qw( Can unlock secret );
my @second = qw( you the code? );
my @newArray = mesh @first, @second;
[download]

List::MoreUtils

Update: Fixed code to adjust to mesh's unusual prototype.

"I am not clear on why there are two 'the the'?"

That is because you are doing:

splice(@newArray3,3,0, @second[1,1]);
[download]

So you are inserting 2 elements "the" in @newArray3 at third position

use strict;
use warnings;

my @first  = qw(Can unlock secret);
my @second = qw(you the code?);

my $i = 1;
while ( my $word = shift @second ){
    splice @first, $i, 0, $word;
    $i += 2;
}

print join ' ', @first;
[download]

Or like this maybe:

use strict;
use warnings;

my @first  = qw(Can unlock secret);
my @second = qw(you the code?);

my $result = join " ", map { ($first[$_], $second[$_]) } (0..$#first);

print $result;
[download]

use strict;
use warnings;

my @first = qw(Can unlock secret);
my @second = qw(you the code?);

splice(@first, $_+1, 0, $second[$_])
    for reverse 0..$#second;

print "@first\n";
[download]

I notice this is fairly close to one of GrandFather's solutions, but that's really because there is only one best way to do this if the requirement is to use splice.

This is a trivial variant of one of the three different splice based options I provided. So which of the trivial variations is "the one best way" to do it? How is this "the best way" if preserving the content of @first is desired? What non-artificial context would require the use of split?

Remember an oft quoted virtue of Perl is TIMTOWTDI with the strong implication that there is seldom a "single best solution". Actually even with languages that tout themselves as offering the "one true way" there is seldom a single "best" solution to any problem.

True laziness is hard work

Thanks Grandfather for those solutions, the best solution I guest is the one that requires the least amount of typing in any language?

Actually, it's an independent solution that just happens to be mostly identical to yours. My determination of "best" is that the OP asked for a solution with splice, and this was the best solution possible with splice. Obviously, splice is not the most efficient way to do this overall, but that's the OP's problem, since he framed the question in the context of splice rather than the context of finding the most efficient way to do merge two arrays. I'm guessing it's a homework problem and they said he had to use splice.