foreach my $key ( keys %ifSpeeds )
{

    if ($counter <= 8) {
        print "$key ";
        $counter++;
    } else { 
        print "$key\n";   #  <--------------
        $counter = 1;
    }
}
[download]

use List::MoreUtils qw(natatime);
my $it = natatime(9, (keys %ifSpeeds));
while (my @vals = $it->()) {
    print "@vals\n";
}
[download]

Hey toolic, thanks for the reply.

Duhh haha... I guess I had a brain fart on that one..! lol thanks.

I was just using the printing as an example. What I'm reallying trying to do is to add 8 consecutive values from the hash and place that summed value in an array.

Using the same hash, would this be what I should do?


my @sum_values;
my $x = 0;

foreach my $key ( keys %ifSpeeds )
{
    if ($counter <= 8) {
        $sum_values[$x] += $ifSpeeds{ $key };
        $counter++;
    } else { 
        $x++;
        $sum_values[$x] = $ifSpeeds{ $key };
        $counter = 1;
    }
}

for (my $x = 0; $x <= $#sum_values; $x++)
{
    print "$x) $sum_values\n";
}
[download]


The final result (given the hash with 32 elements) would be that the array would contains 4 values, which include the following:


   [0] --> (sum of Gi3/1 to Gi3/8)
   [1] --> (sum of Gi3/9 to Gi3/16)
   [2] --> (sum of Gi3/17 to Gi3/24)
   [3] --> (sum of Gi3/25 to Gi3/32)
[download]

Does all that look correct to you?


Thanks Again,
Matt

How about:

use List::MoreUtils qw(natatime);
use List::Util      qw(sum);
use Data::Dumper;

my @sums;
my $it = natatime(8, (values %ifSpeeds));
while (my @vals = $it->()) {
    push @sums, sum(@vals);
}

print Dumper(\@sums);

__END__

$VAR1 = [
          '6200000000',
          '6200000000',
          '6200000000',
          '2600000000'
        ];
[download]

    if ($counter <= 8) {
        $sum_values[$x] += $ifSpeeds{ $key };
        $counter++;
    } else { 
        $x++;
        $sum_values[$x] = $ifSpeeds{ $key };
        $counter = 1;
    }
[download]

To avoid the almost-duplication of the key statement, you could also write

    $sum_values[$x] += $ifSpeeds{ $key };
    $x++ unless ++$counter % 8;
[download]

or even simply

    $sum_values[$counter++/8] += $ifSpeeds{ $key };     # the [] impli
+es int(...)
[download]

(Perl does not generate a warning when you do something like $sum += ..., with $sum being undef initially — it treats it as 0)

I'm wondering why you need a hash. You are indexing anyway so why not just have two arrays, one for the keys and one for the values.

Another thing I notice is that your keys contain an index. Why not use that number as the index for an array that holds the values? When you need to print you can add the Gi3 part in the print statement. An array would let you do the sum of 8 (or more) values at a time. $sum=$a[$n]+$a[$n+1]+ ... You could use a c style for loop to iterate through every 8th index.

From them names I guesstimate he populates this table from the SNMP interface MIB. The index of the ifTable is not necessarily contiguous. Some devices give you 1,2,3.. then jump to 100 or even 1000. So that is not practical as array index. I had the same problem and solved it with hashes plus a custom sort function:

sub sort_by_intf # sort interface alpha/number name mixture properly
{ my $A = $a;    # just turn any number into a 0004 digit one
  my $B = $b;
  $A =~ s/([0-9]+)/ sprintf "%04d",9999-$1 /ge;
  $B =~ s/([0-9]+)/ sprintf "%04d",9999-$1 /ge;
  $B cmp $A; # reverse order happens to be useful here:
}            # Tun0, Ser1, Port-channel2, Gi3, Fa4, Eth5
[download]

Then whenever you loop over the keys, just sort them with that function like so:

for (sort sort_by_intf keys %ifSpeed) {
  printf "intf: %s,  speed: %d\n" $_, $ifSpeed{$_};
}
[download]

If the form of the data is appropriate to a hash then order of elements doesn't matter. If order of elements matters then a hash is not an appropriate representation. Of course it is always reasonable to extract keys or values from a hash into an array and sort that; or sort arrays and assemble them into hashes.

Therefore construct @name_this_array_wisely = keys %ifSpeeds; Sort that array to your taste and iterate through it.