In essence you can't do that. $test contains a Perl regular expression object and JSON doesn't have an out-of-the-box way to deal with them.

If you don't need to round trip the data, but are providing it for consumption elsewhere the allow_blessed function will suppresses the error, insert a 'null', and carry on:

use strict;
use warnings;
use JSON qw();

my $test = {regex => qr/^[\w\@\.]+$/, str => "this is a string"};
my $json = JSON->new();

$json->allow_blessed(1);
print $json->encode($test);
[download]

Prints:

{"str":"this is a string","regex":null}
[download]

Update: and if you do want to round trip it with another Perl script then think about using YAML instead:

use strict;
use warnings;
use YAML qw();

my $test = {regex => qr/\w+\W+(\w+)/, str => "this is a string"};
my $yamlStr = YAML::Dump($test);

print "YAML: $yamlStr\n";

my $andBack = YAML::Load ($yamlStr);
my ($secondWord) = $andBack->{str} =~ $andBack->{regex};

print "Second word is: $secondWord\n";
[download]

Prints:

YAML: ---
regex: !!perl/regexp (?-xism:\w+\W+(\w+))
str: this is a string

Second word is: is
[download]

The problem is that qr/.../ produces a Regexp object (try ref(qr/.../)).

If you know where all the regexes are in your structure, you could convert them all to strings before calling to_json() on them.

{
package Regexp;
sub TO_JSON {
  my $regex = shift;
  $regex = "$regex";
  return $regex;
}

my $json = JSON->new->convert_blessed;
print $json->encode(qr/.../);
[download]

Excellent!

Thanks for showing that this solution exists.

(I hoped it would, but was too lazy to look it up :)

Just one remark: I hope the OP doesn't expect that those RegExes always work in other languages than Perl.

---The Perlman