use warnings;
use strict;

my $primaryFeatures = {
    'foo', ['fool', 'food', 'foot'],
    'bar', ['barricade'],
};

while (my ($key, $value) = each(%$primaryFeatures)){
   print "($key, $_)\n" for @{ $value };
}

__END__

(bar, barricade)
(foo, fool)
(foo, food)
(foo, foot)
[download]

I used square brackets to construct the arrays, then I dereferenced the arrays in the while loop.

It is also customary to use fat commas (=>) when constructing hashes

my $primaryFeatures = {
    foo => ['fool', 'food', 'foot'],
    bar => ['barricade'],
};
[download]

The format of a hash is basically (key, value, key, value, etc.) so, despite adding the parentheses, what you are doing here is mapping foo to fool, food to foot and bar to barricade. An arrayref (reference to an array) is a single value and that's what you should be using here. So, your code becomes:

my $primaryFeatures = {
    'foo', ['fool', 'food', 'foot'],
    'bar', ['barricade'],
};
[download]

You'll need to dereference the arrayref (i.e. @$value) and print each element in some sort of loop. Simplistically, change the print statement to something like:

for my $element (@$value) {
    print "($key, $element)\n";
}
[download]

That should get the code doing what you want. In addition, here's a few other suggestions:

• You can remove much of the punctuation-noise by using => (called the fat comma) and qw{} (quote-on-whitespace): foo => [qw{fool food foot}]
• Unless you really need a hashref, just use a hash: my %primaryFeatures = (...); and later each(%primaryFeatures)
• While there are many ways to do this, while and each are probably not the best choices here (I think you've probably guessed as much already) - for and keys would be better.
• Add use strict; and use warnings; to the top of your code.

Putting all that together, your code might look like:

use strict;
use warnings;

my %primaryFeatures = (
    foo => [qw{fool food foot}],
    bar => [qw{barricade}],
);

for my $key (keys %primaryFeatures) {
    for my $element (@{$primaryFeatures{$key}}) {
        print "($key, $element)\n";
    }
}
[download]

each(), keys() and values() do not guarantee the order of data returned. If you want the exact order you've shown above, you'll need additional code. On my machine, this code outputs:

(bar, barricade)
(foo, fool)
(foo, food)
(foo, foot)
[download]

Finally, what I have here is not so much the correct answer but rather one of many possible working solutions. On this site and in Perl books and documentation you'll often come across the Perl motto: TMTOWTDI (There's more than one way to do it).

my $primaryFeatures = {
    'foo', 'fool', 'food', 'foot',
    'bar', 'barricade',
};
[download]

my $primaryFeatures = {
    foo => 'fool',
    food => 'foot',
    bar => 'barricade',
};
[download]

use warnings;
use strict;

use Data::Dumper;

my $primary_features = {
  foo => [ 'fool', 'food', 'foot', ],
  bar => [ 'barricade' ]
};

print Data::Dumper::Dumper( $primary_features );

while (my ($key, $value) = each(%$primary_features)){
   print "($key, $value)\n";
}
[download]

• I used => instead of ",". They're almost the same, except => puts whatever is to the left of it in quotes, and it's traditionally used to separate the keys and values of things in hash definitions.
• I made a reference to an array with square brackets instead of parentheses. You can make an array with the qw() operator, so qw( fool food fort ) is the same as 'fool', 'food', 'fort' , and may be easier to type.
• When you print out $value, it's going to show something like "ARRAY(0x10080fe18))" that means you're trying to print an array. You can iterate over your array or something like that to print something more useful.
• use warnings and strict. They help you find when you're typing something that doesn't make sense.

~linux> perl -MMath::Cartesian::Product -e 'my %hash = (q|foo|=>[qw|fo
+ol food foot|],q|bar|=>[qw|barricade|]); for (keys %hash) {cartesian 
+{print qq|@_\n|} [$_],$hash{$_}};'
[download]

bar barricade
foo fool
foo food
foo foot
[download]

use 5.010;
my $hash = {
    array_key  => ['one', 'two', 'three'],
    scalar_key => 'four',
};
while (my ($key, $value) = each %$hash) {
    foreach my $element ("ARRAY" eq ref $value ? @$value : $value) {
        say "($key, $element)"
    }
}
[download]