#!/usr/bin/perl -w
use strict;

my $x = 2;
my $y = 3;

my $cmp_result = $x <=> $y;
print $cmp_result  # -1
[download]

for comparison in a string context, use cmp:

my $cmp_result = $stringX cmp $stringY;
[download]

Ken, I really do understand the scope thing. I just screwed it up when I first posted. But given the correct scope...

my $vxdg;
(exists $vxdgs{$node}{$disk})   ? $vxdg=$vxdgs{$node}{$disk}
                                : $vxdg="";
[download]

my $vxdg = exists $vxdgs{$node}{$disk} ? vxdgs{$node}{$disk} : '';
[download]

Both will work (i.e. run without error) but the first form won't do what you're expecting due to operator precedence. The second form is preferable anyway because it is shorter, less complicated and easier to read. Take a look at the perlop manpage - under Conditional Operator for an explanation.

I suggest you write some test code for yourself rather than just asking whether this or that code will or won't work. You can do this sort of thing on the commandline:

ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -E 'my $x = 1 ? 1 : 0; say $x;'
1
ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -E 'my $x; 1 ? $x=1 : $x=0; say $x;'
0
ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -E 'my $x; 1 ? ($x=1) : ($x=0); say $x;'
1
ken@ganymede: ~/tmp
$
[download]

-- Ken

I'm surprised by this result:

ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -E 'my $x; 1 ? $x=1 : $x=0; say $x;'
0
[download]

Do you know why $x becomes 0?

If you want to see how Perl sees and parses your code (and in particular, via the  -p "extra parens, please" switch, how it interprets precedence), use the O and Deparse modules:

>perl -wMstrict -MO=Deparse,-p -le
"my ($node, $disk, %vxdgs) = (0, 0);
 my $vxdg;
 (exists $vxdgs{$node}{$disk}) ? $vxdg = $vxdgs{$node}{$disk}
                               : $vxdg = '';
"
BEGIN { $^W = 1; }
BEGIN { $/ = "\n"; $\ = "\n"; }
use strict 'refs';
(my($node, $disk, %vxdgs) = (0, 0));
my($vxdg);
((exists($vxdgs{$node}{$disk}) ? ($vxdg = $vxdgs{$node}{$disk}) : $vxd
+g) = '');
-e syntax OK
[download]

Ken's comments are "spot on".
The second form is far preferable because it is just far more clear!

There is however another "layer" of complexity to this question that you are probably not aware of....

When testing for the existence of some value in a 2D hash, Perl will "autovivify" the first dimension(s) if it(they) doesn't exist already. The code below demonstrates this behavior. This can lead to some side-effects and strange results later.

This statement:

$var = $vxdg{$node}{$disk} //= '';
[download]

creates the entire multi-dimensional key and assigns it the value of '' if it wasn't already defined. This '//=' operator is specific to Perl. It is like ||= except that it tests for "defined-ness" instead of "truth-ness". Whether or not this is a "good thing" or "not" depends upon the application.

I'm just suggesting that you should be aware of what happens when testing for existence or "defined-ness" of multi-dimensional hash array values.

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my %vxdg;
my $var;

my ($node,$disk) = (3, "C:");
print "node= $node disk=$disk\n";

print "orignal hash is:", Dumper \%vxdg;
print "\$var is: \"", (defined $var) ? $var : "undefined", "\"","\n"; 

$var = exists $vxdg{$node}{$disk} ? $vxdg{$node}{$disk} : '';
print "the hash is now...after checking for",'$vxdg{$node}{$disk}:', 
       "\n", Dumper \%vxdg;
print "\$var is: \"", (defined $var) ? $var : "undefined", "\"","\n"; 

print "\n***Starting over..***\n";
%vxdg=();
$var=undef;

print "orignal hash is:", Dumper \%vxdg;
$var = $vxdg{$node}{$disk} //= '';
print "the hash is now...:", "\n", Dumper \%vxdg;
print "\$var is: \"", (defined $var) ? $var : "undefined", "\"","\n"; 

__END__
node= 3 disk=C:
orignal hash is:$VAR1 = {};
$var is: "undefined"
the hash is now...after checking for$vxdg{$node}{$disk}:
$VAR1 = {
          '3' => {}
        };
$var is: ""

***Starting over..***
orignal hash is:$VAR1 = {};
the hash is now...:
$VAR1 = {
          '3' => {
                   'C:' => ''
                 }
        };
$var is: ""
[download]

Wrong, it can indeed execute code:

sub foo1 { print "Hello, World!\n"; }
sub foo2 { print "Goodbye, World!\n"; }

1 ? foo1() : foo2();
0 ? foo1() : foo2();
[download]

This prints:

Hello, World!
Goodbye, World!
[download]

I think what you're confused about is still scope; like the if/else block in the original post, if you declare my $vxdg inside the ternary operator, it will fall out of scope before you try to access it again.