The first part of the trick is to 'slurp' the file. Set the special variable $/ to undef to read the entire file in one hit:

use strict;
use warnings;

my $file = <<FILE;
1
2
3


FILE

open my $fIn, '<', \$file;
my $str = do {local $/; <$fIn>};
close $fIn;

print "1-->\n$str<--1\n";
$str =~ s/\n+\Z//;
print "2-->\n$str<--2\n";
[download]

Prints:

1-->
1
2
3


<--1
2-->
1
2
3<--2
[download]

Truncating just the superfluous newlines should work, too.  This would avoid rewriting the entire file, and/or reading it into memory.

open my $fh, "+<", $fname or die $!;

my $pos = (-s $fh) - 1;
my $s;
do {
    seek $fh, $pos--, 0;
    read $fh, $s, 1;
} while $s eq "\n";

truncate $fh, $pos + 3;
[download]

(On Windows you'd need to truncate at $pos + 4, or else you'd have just a trailing \r, not a complete \r\n.)

Update: ww remarked via /msg that on Windows ActiveState Perl < 5.14, truncate only works on closed files (according to his tests), but that as of 5.14(.2) it does behave as expected.   I don't have Windows here to verify, so I can only pass this on as is.   Thanks anyway!

What have you tried so far?

When you read an empty line, you can't know yet whether to print it. So you need something along the lines of

my $newlines = 0;
while (<$file>) {
    if (/^$/) {
        $newlines++;
    }
    else {
        print "\n" x $newlines;
        print;
        $newlines = 0;
    }
}
[download]

(untestested).

update: closed regex, ww++.

use Tie::File;

foreach my $filename (grep { -f } @ARGV) {

    print "** Processing $filename\n";

    tie my @file, 'Tie::File', $filename
      or die "Unable to tie: $!\n";

    pop @file while $file[-1] eq q{};

    untie @file
        or die "Unable to untie: $!\n";

    print "** Done...\n\n";
}
[download]

perl -ne'$b.=$_;/./||next;print$b;$b=""' your-file
[download]

Brilliant !!

See also flip, dos2unix, etc.

perl -0pe '~s/\n+$/\n/' your-file
[download]