Can i identify tis pattern (.*|)3 times and have a \n inserted after that?

You haven't mentioned how large the file is.  If it fits into memory, you can read the file into a string and then do

while ($s =~ /(.*?)\|(.*?)\|(.*?)\|/g) {
    print "$1\t$2\t$3\n";
}
[download]

or, if you want to keep the pipe symbols as is

while ($s =~ /((?:.*?\|){3})/g) {
    print "$1\n";
}
[download]

In case the file is huge, you can do instead

local $/ = "|";   # set input record separator

while (<>) {
    print $_, scalar <>, scalar <>, "\n";
}
[download]

(requires that you have multiples of 3 number of "...|" items (when using <>) — otherwise you'd have to test for eof in between reading the records)

Update: or simply use the modulus operator (%) to insert a \n after every 3 records:

local $/ = "|";

while (<>) {
    print;
    print "\n" unless $. % 3;
}
[download]

see readline and split for a start.

#!/usr/bin/perl -w
use strict;

$/="|";
print $_.<DATA>.<DATA>."\n" while (<DATA>);

=prints: 
a|b|c|
d|e|f|
g|h|i|
=cut
__DATA__
a|b|c|d|e|f|g|h|i|
[download]

my $str = 'a|b|c|d|e|f|g|h|i|';
$str =~ s/(?:.*?\|){3}\K/\n/g;
print $str;

__END__
a|b|c|
d|e|f|
g|h|i|
[download]

use strict;
use warnings;

local $/="|"; # Record Separator
my @buf;
while (<DATA>){
  #next unless $_=~/\w/; # Ignore Blank ("\n" lines
  s/\n//; # Zap newlines 
  push @buf,$_;
  Print_It() if (3==@buf);
}
Print_It();
#---------------------
sub Print_It{
      print join("",@buf),"\n";
      @buf=();
}
__DATA__
a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|
s|t|u|v|w|x|y|z|A|B|C|D|E|F|G|H|I|J|
K|L|M|N|O|P|Q|R|S|T|U|V|W|X|Y|Z|1|2|
3|4|5|6|7|8|9|10|11|12|13|14|15|16|17|
18|19|20
[download]