anasuya has asked for the wisdom of the Perl Monks concerning the following question:

Hi. This is in connection with a similar query which I had posted yesterday. I have a file which looks like this. 

 
2gqt_FAD_A_601   =   d.145.1.2-
2i0z_FAD_A_501   =   c.3.1.8-e.74.1.1-

1n1e_NDE_A_400   =   a.100.1.6-c.2.1.6-
2qzl_IXS_A_449   =   b.50.1.2-

2ydx_TXP_E1339   =   c.2.1.2-
3g8i_RO7_A___1   =   c.2.1.2-

1llf_F23_A_800   =   c.69.1.17-
1y0g_8PP_A_320   =   b.61.6.1-

1ewf_PC1_A_577   =   d.83.1.1-
2a94_AP0_A_336   =   c.2.1.5-d.162.1.1-

1fm9_570_D_200   =   a.123.1.1-
2zmh_NYA_A___1   =   a.123.1.1-

[download]

I need to extract out lines, which have dissimilar values after the '=' sign. The output should look something like this: 

 
2gqt_FAD_A_601   =   d.145.1.2-
2i0z_FAD_A_501   =   c.3.1.8-e.74.1.1-

1n1e_NDE_A_400   =   a.100.1.6-c.2.1.6-
2qzl_IXS_A_449   =   b.50.1.2-

1llf_F23_A_800   =   c.69.1.17-
1y0g_8PP_A_320   =   b.61.6.1-

1ewf_PC1_A_577   =   d.83.1.1-
2a94_AP0_A_336   =   c.2.1.5-d.162.1.1-

[download]

How do I do this? Please help.

Replies are listed 'Best First'.
Re: extracting dissimilar lines
by JavaFan (Canon) on Mar 26, 2012 at 09:28 UTC
    Untested: 
    $/ = "";
while (<>) {
    my ($l1, $l2) = split /\n/;
    $l1 =~ /=/p; my $a1 = ${^POSTMATCH};
    $l2 =~ /=/p; my $a2 = ${^POSTMATCH};
    next if $a1 eq $a2;
    print;
}

    [download]
[reply]
[d/l]
      A bit shorter, using no split, no additional variables and only one regex:
      $/ = "";
while (<>) {
    /=\s*([^\n]+).*=\s*([^\n]+)/s;
    print unless $1 eq $2;
}

      [download]

      CountZero

      A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

      My blog: Imperial Deltronics
[reply]
[d/l]
[select]
        That would fail if the second line contains more than one '='. But, if you think there's value in replacing trivial regexes (which can be dealt with by the optimizer) with complicated ones, why not: 
        $/ = "";
/=(\N+)\n[^=]+=\1\n/ or print while <>;

        [download]
        Or, as a one-liner: 
        perl -00ne'/=(\N+)\n[^=]+=\1\n/ or print' data-file

        [download]
[reply]
[d/l]
[select]
Re: extracting dissimilar lines
by stevieb (Canon) on Mar 26, 2012 at 13:38 UTC

    You could *very* easily do this check within this section of the code I wrote for you yesterday in this post

            if ( scalar @hold > 1 ){
            push @data, [ @hold ]; 
        }

    [download]

    What have you tried?

[reply]
[d/l]
Re: extracting dissimilar lines
by trizen (Hermit) on Mar 26, 2012 at 18:28 UTC 
    use 5.010;
while (<>) {
    my $p = /=/p ? ${^POSTMATCH} : next;
    next if (my $c = <>) =~ /=/p and $p eq ${^POSTMATCH};
    say $_, $c;
}

    [download]
[reply]
[d/l]

Back to Seekers of Perl Wisdom