As a general solution to determining the order of operations, you can add the -p option to -MO=Deparse; you write it like -MO=Deparse,-p. This adds parentheses showing how perl parses your code.

ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -MO=Deparse,-p -E '
> my $message = "Congrats" unless not defined $reward;
> '
Global symbol "$reward" requires explicit package name at -e line 2.
-e had compilation errors.
use warnings;
use strict 'refs';
BEGIN {
    $^H{'feature_unicode'} = q(1);
    $^H{'feature_say'} = q(1);
    $^H{'feature_state'} = q(1);
    $^H{'feature_switch'} = q(1);
}
((not defined(${'reward'})) or (my $message = 'Congrats'));
ken@ganymede: ~/tmp
$
[download]

You'll see how you get an error about $message not being declared: this is different from not being defined. Here it is again with this variable being declared but left undefined.

ken@ganymede: ~/tmp
$ perl -Mstrict -Mwarnings -MO=Deparse,-p -E '
> my $reward;
> my $message = "Congrats" unless not defined $reward;
> '
use warnings;
use strict 'refs';
BEGIN {
    $^H{'feature_unicode'} = q(1);
    $^H{'feature_say'} = q(1);
    $^H{'feature_state'} = q(1);
    $^H{'feature_switch'} = q(1);
}
my($reward);
(defined($reward) and (my $message = 'Congrats'));
-e syntax OK
ken@ganymede: ~/tmp
$
[download]

Note differences between the error and error-free versions:

• ((not defined(${'reward'})) or (my $message = 'Congrats'));
• (defined($reward) and (my $message = 'Congrats'));

See also:

• perlrun: command switches, including -M
• O: how -MO is expanded
• B::Deparse: -p and other options

if is not an operator. It's part of the syntax of an if statement. An if statement evaluates its condition first, then evaluates the rest if and only if the condition evaluated to something true.

EXPR if CONDEXPR;
[download]

is exactly the same as

(CONDEXPR) and EXPR;
[download]

By the way,

my $var ... if ...;
[download]

is not allowed. (Same goes for unless.) You should be using

my $message;
$message = "Congrats" if defined $reward;
[download]

or

my $message = $reward ? "Congrats" : undef;
[download]

Not allowed?

$ perl5.15.9 -wE 'my $x = 1 if 2; say $x // "???"'
1
$ perl5.15.9 -wE 'my $x = 1 if 0; say $x // "???"'
???
$
[download]

I won't recommend it, but it is still allowed. I thought it started warning under certain conditions since 5.14, but I'm not able to reproduce it.

The compiler does compile it, but it has been explicitly forbidden in the docs, and it has been so for far far longer than 5.14. (I'm guessing 5.6 or 5.8.)

I hate statement modifiers. All except "for". Anyway, whenever in doubt place parens and/or check:

$ perl -MO=Deparse -e'push @badVals, $val && next if isBad($val);'
push @badVals, $val && next if isBad($val);
-e syntax OK
$ perl -MO=Deparse -e'(push @badVals, $val && next) if isBad($val);'
push @badVals, $val && next if isBad($val);
-e syntax OK
$ perl -MO=Deparse -e'push @badVals, ($val && next) if isBad($val);'
push @badVals, $val && next if isBad($val);
-e syntax OK
$
[download]

Note that all parse the same, and thus probably do not do what you expected it to do. Compare to:

$ perl -MO=Deparse -e'(push @badVals, $val) && next if isBad($val);'
push @badVals, $val and next if isBad($val);
-e syntax OK
$ perl -MO=Deparse,-p -e'push @badVals, $val && next if isBad($val);'
(isBad($val) and push(@badVals, ($val && next)));
-e syntax OK
[download]

update: added -p example after kcott's post.

#!/usr/bin/perl -l

use strictures 1;
no strict 'refs'; 
use Devel::SimpleTrace;

print my $message = 'Congrats' if defined ${'result'};

my @badVals; 
foreach my $val (my(@vals)) { 
    push @badVals, $val && next if isBad($val);
    print "$val is a good val";
} 

sub isBad {...}
[download]