in reply to Doing pair-exclusivity analysis and building a matrix

T'aint pretty, but I think this is what you asked for:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my %names = map{
    my( $name, $rest ) = split;
    $name, { map{ $_, undef } split ',', $rest };
} <DATA>;

my @sortedKeys = sort keys %names;

print "\t", join "\t", @sortedKeys;
for my $i ( @sortedKeys ) {

    printf "%s\t", $i;
    for my $j ( @sortedKeys ) {

        my $nCitiesI = keys %{ $names{ $i } };

        my $nMatchingCitiesJ = grep{
            exists $names{ $j }{ $_ }
        } keys %{ $names{ $i } };

        printf "%d\t", $nCitiesI - $nMatchingCitiesJ;
    }
    print '';
}

__DATA__
Name1  USA,Canada,Yemen
Name2  Canada,Portugal,India
Name3  China,HongKong,Canada
Name4  London,Amsterdam,Ireland,USA
Name5  India,USA,Canada

[download]

Produces:

C:\test>junk.pl
        Name1   Name2   Name3   Name4   Name5
Name1   0       2       2       2       1
Name2   2       0       2       3       1
Name3   2       2       0       3       2
Name4   3       4       4       0       3
Name5   1       1       2       2       0

[download]
With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'
Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
"Science is about questioning the status quo. Questioning authority".
In the absence of evidence, opinion is indistinguishable from prejudice.

The start of some sanity?

Replies are listed 'Best First'.
Re^2: Doing pair-exclusivity analysis and building a matrix
by angerusso (Novice) on Mar 28, 2012 at 02:49 UTC
    Hey, WOw, thanks again so much!! Now I have 3 codes to review. Angel
[reply]

      A couple of minor optimisations:

      #! perl -slw
use strict;
use Data::Dump qw[ pp ];

my %names = map{
    my( $name, $rest ) = split;
    $name, { map{ $_, undef } split ',', $rest };
} <DATA>;

my @sortedKeys = sort keys %names;

print "\t", join "\t", @sortedKeys;
for my $i ( @sortedKeys ) {
    my @keysI = keys %{ $names{ $i } };

    printf "%s\t", $i;
    for my $j ( @sortedKeys ) {

        my $nMatchingCitiesJ = grep{
            exists $names{ $j }{ $_ }
        } @keysI;

        printf "%d\t", @keysI - $nMatchingCitiesJ;
    }
    print '';
}

__DATA__
Name1  USA,Canada,Yemen
Name2  Canada,Portugal,India
Name3  China,HongKong,Canada
Name4  London,Amsterdam,Ireland,USA
Name5  India,USA,Canada

      [download]
      With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'
      Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
      "Science is about questioning the status quo. Questioning authority".
      In the absence of evidence, opinion is indistinguishable from prejudice.

      The start of some sanity?
[reply]
[d/l]

In Section Seekers of Perl Wisdom