You could split the line the first time at the space, assigning the name as the first side of the whitespace and put the rest into another variable, then split the $rest variable on the commas:

#!/usr/bin/perl

use warnings;
use strict;

open my $fh, "<", "infos.txt" or die "cannot open infos.txt: $!";

while ( my $line = <$fh> ){
    chomp $line;

    my ( $name, $rest ) = split /\s+/, $line;

    my ( $age, $gender, $address ) = split /,/, $rest;

    print "Name:    $name\n";
    print "Age:     $age\n";
    print "Gender:  $gender\n";
    print "Address: $address\n";
    print "\n";
}
[download]

Output:

Name:    Mawts
Age:     25
Gender:  female
Address: melbourne

Name:    Awts
Age:     24
Gender:  male
Address: sydney
[download]

Hi stevieb

How about if I put the infos.txt file into a array first and then splitting it from there. like first it will open the .txt file then putting it in a array, then split them inside..

open(INFILE, "<", "infos.txt") or die ("cannot open input: $!");
my @infos = <INFILE>;
chomp(@infos);
[download]

How can I split the datas on my @infos? thanks

It's really not much different. However, slurping in the whole file can run you out of memory if your file is very large.

#!/usr/bin/perl

use warnings;
use strict;

open my $fh, "<", "infos.txt" or die "cannot open infos.txt: $!";

my @array = <$fh>;

close $fh;

for my $line ( @array ){

    chomp $line;

    my ( $name, $rest ) = split /\s+/, $line;

    my ( $age, $gender, $address ) = split /,/, $rest;

    print "Name:    $name\n";
    print "Age:     $age\n";
    print "Gender:  $gender\n";
    print "Address: $address\n";
    print "\n";
}
[download]

Looks like your input file is a CSV (comma separated variable) file so you should use an appropriate CVS module to dot he heavy lifting for you. Text::CSV is a good starting point. Consider:

use strict;
use warnings;
use Text::CSV;

my $filename = 'infos.txt';

open my $fOut, '>', $filename or die "Can't create $filename: $!";
print $fOut <<TEST;
Mawts 25,female,melbourne
Awts 24,male,sydney
TEST
close $fOut;

my $parser = Text::CSV->new();

open my $fIn, '<', $filename or die "Can't open $filename: $!";

while (my $row = $parser->getline($fIn)) {
    my ($name, $age) = $row->[0] =~ /(.*)\s(\d+)/;

    print "Name:    $name\n";
    print "Age:     $age\n";
    print "Gender:  $row->[1]\n";
    print "Address: $row->[2]\n\n";
}

close $fIn;
[download]

Prints:

Name:    Mawts
Age:     25
Gender:  female
Address: melbourne

Name:    Awts
Age:     24
Gender:  male
Address: sydney
[download]

#!/usr/bin/perl --
use strict; use warnings;
use Data::Dump qw/ dd /;

my( $left, $right, $righter ) = split ',', 'Mawts 25,female,melbourne'
+;

my( $name, $age ) = split ' ', $left;

dd [ $left, $right, $righter ];
dd [ $name, $age];
__END__
["Mawts 25", "female", "melbourne"]
["Mawts", 25]
[download]

• Split multiple times, using multiple statements.   This is no time for “golf.”   Keep it simple and direct.
• If the problem appears to be one that has already been dealt with by a CPAN module, e.g. Text::CSV, use it in preference to a hand-made solution.
• Get to know the many modules in Regexp::Common.   (Do a search ... there are many more than just the ones that the hotlink above will show you.)

Wonderful addition to the thread, its as if none offered code that did exactly this

Never said they didn’t, now did I?   Addressing a particular reply “very specifically” is great of course, for that person who is at that particular moment being addressed.   But any thread that is written on this forum is going to last for dozens of years, and every single bloke who encounters it in the future is not going to have “exactly this same problem.”   (And, they just might not want to wade through even a paragraph or two of “Perl code.”   Or, they might feel about my post exactly the same way you did.   Who knows?   Certainly not gonna self-censor the thread for worrying about such things.)

I just pointed out a few things that, well do I remember from the time, I didn’t know at the time, and as a consequence, spent more effort on than I really needed to.   I would have found my comment useful.   (Soapboxing a bit here ...)   The real value of Perl is the vast CPAN library that goes with it.   But “vast” means that there are a helluva lot of things in there that maybe you had no idea were there.   We all have had the experience of writing something from scratch not knowing that something better was at-hand, and maybe benefiting from just a little nudge in an unexpected direction.

I’m never commenting on anything to hear myself talk, and I have a Rhett Butler attitude about “XP.”   I have no idea who’s gonna find what useful, nor when nor why.   Just gonna do my best.