What happens if you get the same value in two different matches?

open O, ">$r" or die $!;

Ok, you solved problem, but let's make the post worth while by passing on the usual round of "wisdom". Consider:

#!/usr/bin/perl
# chess.plx
use warnings;
use strict;

use utf8;

my $filename = "thaikjv-fixed.txt";

open my $fIn, '<', $filename or die "Can't open $filename: $!\n";
binmode ($fIn, ":utf8");

while (defined (my $line = <$fIn>)) {
    next if $line !~ /^@(...\d\d\d)/;
    
    my $outname = "$1.html";
    
    open my $fOut, '>', $outname or die "Can't create $outname: $!\n";
    binmode ($fOut, ":utf8");
    print $fOut $line;
    print "hi";
    close $fOut;
}
[download]

Note:

• use three parameter version of open and lexical file handles
• show the file name in errors
• use a while loop instead of a for loop when reading files
• use early exit to avoid extra levels of indentation
• avoid using the default variable across multiple lines
True laziness is hard work

One can even unify the calls to open and binmode:

open my $fOut, '>:utf8', $outname or die "Can't create $outname: $!\n"
+;
[download]

Perl 6 - second systems done right

I'd suggest to use while(<FH>) instead of foreach(<FH>). (while loop reads directly from file, for(each) loop slurps the entire file into memory first - really bad for huge files, but ok for small ones).

Maybe something like this:

use strict;
use warnings;

open my $thai_fh, '<:utf8', "thaikjv-fixed.txt" or die $!;

while(<$thai_fh>){
    if (/^@(...\d\d\d)/) {
        open my $out_fh, '>:utf8', "$1.html" or die $!;
        print {$out_fh} $_;
    }
}
[download]

/code

This should work for you

#!/usr/bin/perl
use warnings;
use strict;

use utf8;
my $filename = "thaikjv-fixed.txt";

open my $THAI, $filename or die $!\n";
binmode ($THAI, ":utf8");

while (<$THAI>) {
    chomp $_;
    
    if ($_ =~ m/^@(...\d\d\d)/){
        my $r = "$1.html";
        open my $OUT, '>', $r or die $!\n";
        binmode ($OUT, ":utf8");
        print $OUT $line;
        close($OUT);
    }
}
close($THAI);
[download]