There are several resources that can help you. I have written Character Encodings in Perl, and there's also the Perl Programming Unicode/UTF-8 wikibook.

The simplest advice boils down to decoding everything that comes into your program, and encoding everything that leaves your program.

All in all encoding problems are not really different than any other bugs where wrong output is produced. The real problems is that often programmers don't have a clear mental image of how which data source encodes its strings, and what the modules they use do with those strings.

tchrist suggests all scripts dealing with Unicode start like this( from his slideshow): Its simple isn't it? heh heh:-)

#!/usr/bin/env perl
 use v5.14;
 use utf8;
 use strict;
 use autodie;
 use warnings; 
 use warnings    qw< FATAL utf8 >;
 use open        qw< :std :encoding(UTF-8) >;
 use charnames   qw< :full >;
 use feature     qw< unicode_strings >; 

#The First of these is almost always needed; the rest, not so much.
 use Unicode::Normalize  qw< NFD NFC >;
 use Encode              qw< encode decode >;
 use Carp                qw< carp croak confess cluck >;
 use File::Basename      qw< basename >;

 $0 = basename($0);  # shorter messages 

binmode(DATA, ":encoding(UTF-8)");
 
 # This works like perl -CA: note that it
 # assumes your terminal is set to use UTF-8
 if (grep /\P{ASCII}/ => @ARGV) { 
    @ARGV = map { decode("UTF-8", $_) } @ARGV;
 }
 
 $| = 1;   # comment out for performance
 END { close STDOUT } 

#This avoids compile-time “bugs” in the pragma:
# XXX: use warnings FATAL => "all";
 
 local $SIG{__DIE__} = sub {
     confess "Uncaught exception: @_" unless $^S;
 };
 
 local $SIG{__WARN__} = sub {
     if ($^S) { cluck   "Trapped warning: @_" } 
     else     { confess "Deadly warning: @_"  }
 }; 

# I use this on normal CLI filters:
 if (@ARGV == 0 && -t STDIN && -t STDERR) {
    print STDERR "$0: reading input from tty, type ^D for EOF...\n";
 }

 while (<>)  {
     chomp;
     $_ = NFD($_);
     ...
 } continue {
     say NFC($_);
 }
 
__END__
[download]

a) The encoding of the script is not relevant to the encoding of the data manipulated by the process as long as you indicate to perl what the script encoding is if you use non-ascii literals in it. See: encoding

b) Don't worry about (or rely on an assumption about) what internal coding perl uses. http://http://perldoc.perl.org/perlunifaq.html#I-lost-track%3B-what-encoding-is-the-internal-format-really%3F

c) If you know what the encoding of the data you are reading is, use decode() on it, or binmode(:encoding(xxx)) on the filehandle. This will convert it into the internal encoding so you can do what have you, such as encode() it into some different encoding.

binmode Encode

d) If you don't know what the encoding of read data is, that's problematic. There isn't a definitive way to sort them out.

See also Tutorials: perlunitut: Unicode in Perl, perluniintro, Perl Unicode Essentials

Let's say that the preferred "destination data", regardless of it's original encoding, is supposed to be ISO-8859-1

Of course, it's possible to use an encoding which uses nothing but characters from ISO-8859-1, or even printable ASCII. HTML numeric entities are one such an encoding. Or Perls \x{} escapes. You'd still need a mapping from numbers to meanings somewhere (perhaps you could borrow the Unicode mapping, but there are also encodings for scripts that use characters that are not defined in Unicode -- Klingon for instance)

2. Let's say that the preferred "destination data", regardless of it's original encoding, is supposed to be ISO-8859-1. How can I accomplish this? Automatically or semi-automatically?