Just a thought. Here is a basic example of running the 'bc' calculator and collecting the STDOUT and STDERR separately. So, you could drop in your program, and watch the STDOUT and STDERR streams for your special prompt, then play a sound or ring the bell, or whatever, even automatically write to STDIN if the special user prompt is seen. This script could be put into the background by running it with an &, like ./myscript &

#!/usr/bin/perl
use warnings;
use strict;
use IPC::Open3;
use IO::Select;

#interface to "bc" calculator
my $pid = open3(\*WRITE, \*READ,\*ERROR,"bc");
            #if \*ERROR is false, STDERR is sent to STDOUT 

my $selread = new IO::Select();
my $selerror = new IO::Select();
$selread->add(\*READ);
$selerror->add(\*ERROR);
# may not be best use of IO::Select, but it works :-)

my($error,$answer)=('','');

while(1){

print "Enter expression for bc, i.e. 2 + 2\n";
chomp(my $query = <STDIN>);

#send query to bc
print WRITE "$query\n";

#timing delay needed tp let bc output
select(undef,undef,undef,.01); 

#see which filehandles have output
if($selread->can_read(0)){print "ready->read\n"}
if($selerror->can_read(0)){print "ready->error\n"}
 
#get any error from bc
sysread(ERROR,$error,4096) if $selerror->can_read(0);
if($error){print "\e[1;31m ERROR-> $error \e[0m \n"}

#get the answer from bc
sysread(READ,$answer,4096) if $selread->can_read(0);
if($answer){print "$query = $answer\n"}

($error,$answer)=('','');
}

waitpid($pid, 1);
# It is important to waitpid on your child process,  
# otherwise zombies could be created.
[download]