It sounds like you'd be fine with processing them one at a time, not all at once. In that case, just wrap your while loop in another loop that goes through the files:

my @files = qw( /path/to/file1
                /path/to/file2
                /path/to/file3
               );

for my $file (@files){
  open my $fd, '<', $file or die $!;
  while(my $line = <$fd>){
      # do stuff with the next line
  }
  close $fd;
}
[download]

Use <> (instead of <FILE1>) and specify the files as command line arguments (or manually put them in @ARGV).

cat *.log | your_script > modified.log-data
[download]

#!/usr/bin/perl

use strict;

while (<>) {
    # do stuff here, then...
    print;
}
[download]

cat *.log | your_script > modified.log-data

Why use cat when Perl can do it all by itself?  With the added benefit of $ARGV letting you know which file you're working on, and being able to do in-place edits via -i / $^I:

$ cat *.log
bar1
bar2
bar3
baz1
baz2
baz3
foo1
foo2
foo3

$ perl -ne 'print "$ARGV: $_"' *.log
bar.log: bar1
bar.log: bar2
bar.log: bar3
baz.log: baz1
baz.log: baz2
baz.log: baz3
foo.log: foo1
foo.log: foo2
foo.log: foo3

$ cat *.log | perl -ne 'print "$ARGV: $_"'
-: bar1
-: bar2
-: bar3
-: baz1
-: baz2
-: baz3
-: foo1
-: foo2
-: foo3

$ perl -i -ne 'print ucfirst $_' *.log
$ cat *.log
Bar1
Bar2
Bar3
Baz1
Baz2
Baz3
Foo1
Foo2
Foo3
[download]

(note to the OP:  -n is the short "command line" version of saying while (<>) { ... } — see perl -h )

# Edit-in-place in multiple files - one file at the time

{
    local $^I = q{};
    local @ARGV = @files;
    while(defined(my $line = <>)){
        # do something with $line
    }
    continue {
        print $line;
    }
}
[download]

# Read multiple lines from multiple files at the same time

my @files = @ARGV;

my @fh;
my $i = 0;
foreach my $file (@files) {
    -f -r $file or next;
    open $fh[$i++], '<', $file
      or die "Cannot open $file: $!";
}

while (1) {
    my @lines;
    foreach my $i (0 .. $#fh) {
        ref $fh[$i] eq 'GLOB' or next;
        push @lines, scalar readline $fh[$i];
        if (eof $fh[$i]) {
            close $fh[$i];
            $fh[$i] = undef;
        }
    }
    @lines or last;
    foreach my $line (@lines) {
        # do something with $line
    }
}
[download]

How can Anonymous Monks edit their nodes??

I'm pretty confident that the first time I saw this reply, there was only the part up to the "or" ...

What you saw was database hiccup

#Find the CHAN pair
            if( $UNID[1] eq $UNID[$x] )
            {
                #Temporary variable to store the CHAN
                $channel2 = $CHAN[$x];
                
                #Creates a loop counter
                $y = 1;
                #Tracks if the changes have been complete
                $complete = 0;
                
                #Search the files for the instancs of the CHAN
                while( ( $y < scalar( @FILES ) ) && ( $complete == 0 )
+ )
                {
                    #Open the file for replacement
                    open $fd, '<', $FILES[ $y ];
                    #Creates a backup of the original file
                    $^I = '.bac';
                    
                    @file = <$fd>;
                    
                    seek $fd, 0, 0;
                    
                    print "$channel1 and $channel2\n";
                    
                    foreach $file ( @file )
                    {
                        $file =~ s/$channel2/$channel1/ or die $!;
                    }
                    
                    #Close the file that was searched
                    close $fd;
                    
                    $y++;
                }#End replacing while
                
                #Remove the used entries from the array
                delete $CHAN[1];
                delete $UNID[1];
                delete $CHAN[$x];
                delete $UNID[$x];
    
                #Force the loop to end
                $found = 1;
            }#End pair find if
[download]