use warnings;
use strict;
use Data::Dumper;

my $str = 'deadbeef';
my @bytes = $str =~ /../g;
print Dumper(\@bytes);

__END__

$VAR1 = [
          'de',
          'ad',
          'be',
          'ef'
        ];
[download]

If you are interested in learning Perl, here are some free-sources (I just made that up, I think):

• perlintro
• perlre
• print
• Data::Dumper

Welcome to the Monastery!

While I'm sure someone proficient in Java is surely reading your post by now, it would help those of us such as myself (who have been fortunate enough to keep our distance from Java) if you could explain what it does. I have some ideas, but I would enjoy thinking about how to implement it in Perl a lot more if I was sure what it does.

Assuming you get a maximum of four hex digits in a number between dashes (otherwise the semantics of the Java version would be rather obscure too), I'd say:

sub get_bytes {
    return join '', map {
        length($_) > 2 ? pack('C', hex substr($_,0,-2)) : pack('C', he
+x $_)
    } split /-/, $_[0];
}
[download]

It splits the string on dashes, the resulting list gets mapped to characters depending on the length of the number (I leave off the last two hex digits rather than doing a logical right shift because pack returns a string) and then joined back together with no separator to yield the byte string.

Maybe someone can come up with a clever pack pattern that does it all, I'm not quite the expert there.

As pack 'H' is working from left to right on the passed string, you can simply say pack 'H2' (two hex characters make up one byte):

sub get_bytes {
    return join '', map {
        pack('H2', $_)
    } split /-/, $_[0];
}

print get_bytes('66-6f-6f00-62ff-61-72');
[download]

This would print "foobar", because the lower bytes 00 and ff are being ignored.

Perhaps:

sub dashedHexToBytes{ 
    join'', map pack( 'H*', $_ ),split'-', $_[0] 
};;
[download]

print dashedHexToBytes( '3f-ff0c-1234-af12' );;
? ♀↕4»↕

Or

sub dashedHexToBytes{ 
    local $_ = shift; 
    tr[-][]; 
    return pack( 'h*', $_ );
};;
[download]

print dashedHexToBytes( '0123-4567-89ab-cdef-0123-4567-89ab-cdef' );;
►2MeÎÿ║═Ý▀►2MeÎÿ║═Ý☼

Note: In both examples, you may need to switch from 'H*' to 'h*' or vice versa depending on the endianess of the originating system and that of the receiving system.

This solution did the trick, got the result into a binary exactly as we needed! Thanks so much and sorry for the delay in getting my response back up here.

sub dashedHexToBytes{ 
    join'', map pack( 'H*', $_ ),split'-', $_[0] 
};
[download]

Best! Jaakko

#!/usr/bin/perl
use strict;
use warnings FATAL => qw(all);

sub getBytes {
# split string into tokens
    my @tokens = split '-', (shift);

# map array of hex tokens to array of bytes
    my @bytearray = map (
        pack('C', hex2byte($_)), # see below
        @tokens
    );

    return \@bytearray;
}

sub hex2byte {
    my $b = hex(shift);
# deal with oversize values
    $b >>= 1 while ($b > 255);
    return $b;
}

# try
my $arrayref = getBytes('5e-ff-adad-23');

# check
foreach (@{$arrayref}) {
    print unpack ('C', $_)."\n";
}
[download]