Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

This works,('min23' in haystack is replaced by 'new') but it seems messy. 
use strict;
use warnings;

my $needle = 'mo4\dy13\hr19\\'; #escape final backslash
$needle =~ s/\\/\\\\/g; # escape all backslashes or they will mess up 
+the regex
my $haystack = '\yr2012\mo4\dy13\hr19\min23\sec51';
if ($haystack =~ /$needle(.*?3)/) {
  print "found $1\n";
  my $match = $1;
  my $replacement = 'new';
  my $newneedle = $needle;
  $newneedle =~ s/\\\\/\\/g; # unescape the backslashes or there will 
+be too many in the final string
  $haystack =~ s/$needle$match/$newneedle$replacement/; # I want all v
+ariables here, not literal strings
} else {
  print "not found\n";
}
print "$haystack\n";

[download]
  • Comment on Is there a nicer way to do regex search and replace with literal backslashes?
  • Download Code

Replies are listed 'Best First'.
Re: Is there a nicer way to do regex search and replace with literal backslashes?
by davido (Cardinal) on Apr 14, 2012 at 21:51 UTC

    I think this is what you were going for:

    my $needle = 'mo4\dy13\hr19\\';
my $haystack = '\yr2012\mo4\dy13\hr19\min23\sec51';

$haystack =~ s/\Q$needle\E([^3]*3)/${needle}new/;

print 'Final $haystack:', $haystack, "\n";

    [download]

    If you look up quotemeta, or perlretut you'll see discussion on the \Q...\E metacharacters and how they simplify escaping of strings.


    Dave

[reply]
[d/l]
[select]

      Here are examples using both davido's code and a version with the 5.10+  \K regex metacharacter (operator?). 

      >perl -wMstrict -le
"my $needle = 'mo4\dy13\hr19\\';
 my $h1 = my $h2 = '\yr2012\mo4\dy13\hr19\min23\sec51';
 ;;
 print qq{'$h1'};
 $h1 =~ s/\Q$needle\E([^3]*3)/${needle}new/;
 print qq{'$h1'};
 ;;
 print qq{'$h2'};
 $h2 =~ s{ \Q$needle\E \K [^3]* 3 }{new}xms;
 print qq{'$h2'};
 ;;
 $h1 eq $h2 or die 'oops...';
"
'\yr2012\mo4\dy13\hr19\min23\sec51'
'\yr2012\mo4\dy13\hr19\new\sec51'
'\yr2012\mo4\dy13\hr19\min23\sec51'
'\yr2012\mo4\dy13\hr19\new\sec51'

      [download]
[reply]
[d/l]
[select]

        Very nice.

        It's one thing to read it in the POD, and another entirely to commit the use of a new tool to habit. After seeing your concise illustration I think it will stick in my head this time. :)


        Dave

[reply]
Re: Is there a nicer way to do regex search and replace with literal backslashes?
by moritz (Cardinal) on Apr 14, 2012 at 21:19 UTC
[reply]
[d/l]

Back to Seekers of Perl Wisdom