Re^2: Print Number With Implied Decimal Point

use bigint applied globally severely distorts the results.

As both of your test cases work on strings anyway, you'd get a more useful comparison when restricting the scope of bigint to where it's required.

With your original version, I get on my machine:

        Rate substr  regex
substr 481/s     --   -14%
regex  558/s    16%     --
[download]

while with the restricted scope of bigint, I get

#!/usr/bin/perl
use warnings;
use strict;
use feature 'say';
use Benchmark qw/cmpthese/;

my @list;
{
    use bigint;
    
    my @chars = ('0' .. '9', 'a' .. 'f');
    
    @list = map {join q(), map $chars[rand @chars], 1 .. 32} 1 .. 100;
    say for @list;
    $_ = (hex $_)."" for @list;
    say for @list;
}

cmpthese(0, {
              substr => sub {
                  my @l = @list;
                  substr $_, -2, 0, '.' for @l;
              },
              regex => sub {
                  my @l = @list;
                  s/(..)$/.$1/ for @l;
              }
});

__END__
          Rate  regex substr
regex   5672/s     --   -80%
substr 28469/s   402%     --
[download]

Comment on Re^2: Print Number With Implied Decimal Point Select or Download Code

Replies are listed 'Best First'.
Re^3: Print Number With Implied Decimal Point by kennethk (Abbot) on Apr 18, 2012 at 15:38 UTC
Note that with a properly crafted regex, the timing difference between it and substr is pretty small; limiting the scope of bigint and using the look-ahead regex from Re^2: Print Number With Implied Decimal Point: `Rate regex substr regex2 regex 2926/s -- -78% -80% substr 13087/s 347% -- -11% regex2 14782/s 405% 13% --` [download] Update: see Re^2: Print Number With Implied Decimal Point #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.	[reply] [d/l]
Re^4: Print Number With Implied Decimal Point by Eliya (Vicar) on Apr 18, 2012 at 15:46 UTC
the timing difference between it and substr is pretty small Yes, sure. My main point was the side effects of applying `use bigint` globally (which completely washes out any difference there might be), and not so much to support that substr is faster than regex.	[reply] [d/l]
Re^3: Print Number With Implied Decimal Point by j355ga (Initiate) on Apr 19, 2012 at 14:01 UTC
Limiting the bigint scope makes a HUGE difference in my tests. 2,100 rows per second vs 700 per sec. Thanks for the tip!	[reply]