use List::Util qw( max );
use POSIX      qw( strftime );

my %by_date;
for my $time (@times) {
   my $date = strftime('%Y-%m-%d', localtime($time));
   $by_date{$date} = max($by_date{$date}||0, $time);
}

my @filtered_times = map $by_date{$_}, sort keys(%by_date);
[download]

One second thought, the following seems better, especially if the initial list of times is already sorted.

use POSIX qw( strftime );

my $last_date = '';
my @filtered_times;
for my $time (sort { $a <=> $b } @times) {
   my $date = strftime('%Y-%m-%d', localtime($time));
   if ($date eq $last_date) {
      $filtered_times[-1] = $time;
   } else {
      push @filtered_times, $time;
      $last_date = $date;
   }
}
[download]

I like this solution.

However, my suggestion would be to use gmtime instead of localtime and use the same algorithm. But that of course depends upon what the OP is really trying to do. I didn't see anything in the problem statement about local time. Epoch time is a monotonically increasing number of seconds from an arbitrary start time. Weird things can happen when translating UTC (GMT) based time back into a local time.

For a wild example: Samoa changes Date/Time Line. Smaller versions of this happens when we change between Summer and Winter time.

I didn't see anything in the problem statement about local time

I do not consider "sometimes 8pm to 8pm and sometimes 7pm to 7pm" to be the default definition of "day".

I would have thought that if someone says today without qualification, that means midnight to midnight where he is observing. Even if every day is not the same length. I don't know why you're assuming he wants the date somewhere else in the world.

But yes, any time zone's day could be used by the solution I posted.

If you could post a short example with the code that you have so far, that would be very helpful.

You could probably do something like this:

# assuming @epoch_times contains the data

use constant ONE_DAY => 84_600; # seconds per day

my %per_day;
for my $time ( @epoch_times ) {
    my $key = int $time / ONE_DAY;
    if ( exists $per_day{ $key } ) {
        $per_day{ $key } = $time if $per_day{ $key } < $time;
        }
    else {
        $per_day{ $key } = $time;
        }
    }

@epoch_times = values %per_day;
[download]

But only if your input data is already sorted...

;-)

Update: And assuming (cf. Marshall's question above) that by "largest" you mean "latest".

Update 2: And of course if your date-times go back to more than 10 years ago (more precisely, to before 9 Sep 2001 03:46:40), the sort needs to be replaced by sort { $a <=> $b }.

Assuming that by 'epoch time' you mean time_t, you don't need to convert to some other form. Since time_t is a lying liar and pretends every day is exactly 86400 seconds long, you can just do some /'s and %'s to find which fit in the same day and the highest for the day.

(of course, because of the undefined behavior around leap seconds, you can't really be sure whether % 86_400 == 0 is actually 00:00:00 or 23:59:60, but I think most systems repeat the 86399th instead. And since you can't tell anyway, it probably doesn't matter)

Hi,

Perhaps sorting the date-times in reverse order?

Then you each time the date part changes you have the latest time for that day.

J.C.