Others have already commented on better ways to achieve what you want. Let me try to explain your mistake:

my @names = map {$i > 6 ? push(@names,$input2arr[$i]) : $i++ } @input2arr;

pushing to the array @names inside the map block is wrong. Because map aggregates all return values from the block, and then assign them to @names, so all your previous changes are lost.

Or phrased differently, if you just return those elements, map will do the pushing for you.

My first response would be why? map is used (usually) when you want to modify a list of values and use the modified list. In my opinion, what you are doing is clearer being done with a for loop.

Reformatted:

my @names = map {                    # 1, 3
    $i > 6                           # 2, 4
       ? push(@names,$input2arr[$i]) # 1, 2
       : $i++;                       # 2
} @input2arr;
[download]

• 1) You are assigning the results of the map call to @names and modifying it within the map call. Don't do that. It will not do what your original for loop does.
• 2) push returns the number of elements after the push in @names. The tristate ( A ? B : C returns either the size of @names when a push happens, or the value of the counter $i.
• 3) @names, I believe, will end up with the value ( 0, 1, 2, 3, 4, 5, 6). It is also possible that it is undefined behavior.
• 4) $i is not defined. I am assuming that, in numeric form, it starts at 0.

If you didn't want to use the for construct, perhaps the 'x' operator, splice, or even a straight assignment would be better.

Update: Since others posted before I completed mine, this block of code illustrates what you would be seeing:

@x = map {
  $r = push(@x, $_);
  print(join(",", @x),"\n");
  $r;
} qw(a b c d e);
print join(",", @x), "\n";
__DATA__
a
a,b
a,b,c
a,b,c,d
a,b,c,d,e
1,2,3,4,5
[download]

my $input = ':xxx xxxxx = #xxx :xxx @rndletters @rndletters';
my @names = split //, substr $input, 7;
[download]

Barring that, that's not how map functions work. Map takes a list and performs an operation on each element, returning the result. You are thinking of it more as a foreach, which is not what it's intended for. If you really want to use map, you could use an iterator and return an empty list:

my $i = 1;
my @names = map {++$i > 6 ? $_ : () } @input2arr;
[download]

my $i = 1;
my @names = grep {++$i > 6} @input2arr;
[download]

But neither of these is particularly transparent.

This bit is quite wrong:

my @names = map {$i > 6 ? push(@names,$input2arr[$i]) : $i++ } @input2
+arr;
[download]

Inside the map block (i.e. the bit between { and }) you don't just put the equivalent of what you'd put inside a foreach block. Allow me to demonstrate with a simple example...

my @letters  = ('a', 'b', 'c');
my @capitals;
foreach my $l (@letters) {
  push @capitals, uc($l);
}
[download]

Don't do this:

my @letters  = ('a', 'b', 'c');
my @capitals = map { $i++; push @capitals, uc($letters[$i]) } @letters
+;
[download]

Do this:

my @letters  = ('a', 'b', 'c');
my @capitals = map { uc($_) } @letters;
[download]

What map does basically is to execute the contents of the block on each item in the given list, making a new list from all the results. Note in the above example, the code within the block doesn't need to do any pushing onto @capitals, and it doesn't need to look at @letters - the map function does that for you.

Your particular example can be written as:

my $i = 0;
my @names = map { $i++ > 6 ? ($_) : () } @input2arr;
[download]

Though using grep in this case might be better.

my $i = 0;
my @names = grep { $i++ > 6 } @input2arr;
[download]

Or just use an array slice:

my @names = @input2arr[ 7 .. $#input2arr ];
[download]

thank you everyone for the help :) i learnt allot from this info :)