You should probably read them into a hash:

my %vals;
open my $infile, '<', 'data.txt' or die $!;
while( <$infile> ) {
    chomp;
    my( $identifier, $value ) = split /\s*=\s*/;
    $vals{$identifier} = $value;
}
close $infile;

my $calculation = $vals{x1} * $vals{y1};
$calculation = ( $vals{x1} * $vals{y1} ) / $vals{x2};
[download]

I gather you had something else in mind, such as importing the identifiers as fully fledged variables into your program, which is often (meaning almost always) a bad idea. For reference on that topic:

• perldoc perlref "Symbolic References"
• Why it's stupid to 'use a variable as a variable name': Part I
• Why it's stupid to 'use a variable as a variable name': Part II
• Why it's stupid to 'use a variable as a variable name': Part III

Symbolic references are incredibly useful under the right circumstances. And in the general course of writing a well designed Perl program those circumstances are rare.

I happen to have written a module which understands that syntax. You could use it like this:

use strict;
use warnings;
use 5.010;
use Math::Expression::Evaluator;

my $m = Math::Expression::Evaluator->new;
# read all the variables
$m->parse("x1=3.8; x2=5.8; x3=4.1; y1=10.1; y2=11.6; y3=12.7")->val;

# do the calculations you are interested in:
say $m->parse("x1 *  x2")->val;
[download]

Not saying it's the best solution, it just happens to work :-)

open; split and on-and-on....

or, if your learning style is compatible with examples...check Super Search for threads here dealing with the issues you face, and see also http://www.perlmonks.com/index.pl?node=Tutorials#Input-and-the IO tut in our Tutorials section.

But a couple points about your question:

1. Is the data sample you posted an example of a single line (record) in data.txt or are each of the label:value pairs on a separate line or something else entirely? (Implicit hint made explicit: your questions will generally get quicker and better help if your problem statement is precise.)
2. Your question suggests that you might hope to learn Perl by studying the syntax of some functions. That's probably sub-optimal. The "chapters" element is likely a better route, and which text to recommend depends (to some extent) on the extent your prior experience as a programmer.
   But without that info, it's hard to do better than recommending Learning Perl, 6th ed. But beware: the first several hits if you simply Google the title appear to be UNauthorized ... ie, ripoffs of the authors and O'Reilly.

Edits for fact, spelling and references. Aaagh!

use 5.010;
use strict;
use warnings;

$_ = `cat data.txt`;
s/\b[a-z]/\$::$&/g;
eval;

no warnings 'once';
say $::x1 * $::y1;
say $::x2 * $::y2;
say $::x3 * $::y3;
say +($::x1 * $::y1) / $::x2;

__END__
38.38
67.28
52.07
6.61724137931034483
[download]