You're in one-liner terrritory, but the syntax can be a bit tricky. The quotes and backslash in -F"\|" are both required (at least on a windows shell):

C:\test>copy con junk.csv
NAME|AGE|CITY|ZIP
AAA|23|STAT|60001
BBB|34|PPOR|12345
CCC|11|TRET|2345
^Z
        1 file(s) copied.

C:\test>perl -F"\|" -anle"print join'|', @F[ 0,2 ]" junk.csv
NAME|CITY
AAA|STAT
BBB|PPOR
CCC|TRET
[download]

Thank you BrowserUK :)

To be honest, I haven't often used slices... if I wanted to change the column name(s) I want selected on the fly, could that be fit into this one-liner equation relatively easily? (I'm well past the OP's problem, I'm curious for myself now)

Still room for optimization, but here it is (Linux style quotes used):

 perl -F"\|" -anlE'%x= %x?%x:(map{$_=>$i++}@F);print "$F[ $x{NAME}]|$F
+[$x{ZIP} ]"' junk2.txt
[download]

(Unwound the slice, and used Names as indexes)

             I hope life isn't a big joke, because I don't get it.
                   -SNL

if I wanted to change the column name(s) I want selected on the fly, could that be fit into this one-liner equation relatively easily?

If you mean "change which columns are selected", or their ordering, that's trivial:

C:\test>perl -F"\|" -anle"print join'|', @F[ 1,3, 0,2 ]" junk.csv
AGE|ZIP|NAME|CITY
23|60001|AAA|STAT
34|12345|BBB|PPOR
11|2345|CCC|TRET
[download]

If you want to select by column name, that's a bit harder to do as a one-liner:

C:\test>perl -F"\|" -anle"$n=0;if($.==1){ %names=map{$_,$n++}@F;next};
+ print join'|', @F[@names{'AGE','NAME'}]" junk.csv
23|AAA
34|BBB
11|CCC
[download]

But why would you want to do that as a one liner? (Ie. Why would you use the names rather than the column numbers directly in a one-liner?)

If you want to write a script that gets names from the command line and uses that to select columns from a file:

#! perl -slw
use strict;

my @selection = delete @ARGV[ 1 .. $#ARGV ];
my $n = 0;
my @colnames = split /\|/, scalar <>;
my %colnames = map{ $_ => $n++ } @colnames;

print join '|',@colnames[ @colnames{ @selection } ];

while( <> ) {
    print join '|', ( split '\|' )[ @colnames{ @selection } ];
}

__END__
C:\test>junk.pl junk.csv AGE NAME
AGE|NAME
23|AAA
34|BBB
11|CCC
[download]

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

The start of some sanity?

#!/usr/bin/perl -w
use strict;

while (<DATA>)
{
   chomp;  # deletes line ending, 
           # If this is a file:
           # Windows,  Unix, Old Apple
           # <CR><LF>, <LF>, <CR> doesn't matter at all
           # Perl chomp() in text mode handles all that.
           
           # allows $zip to be used in future code
           # as index [3] without having to worry about
           # the line ending after the zip code...
   
   # assign name and city to index [0,2] respectively
   # using list slice

   # just split() upon the '|" character. 
   # many dataBsase export formats use '|' as a field separator.
   # instead of a "," to make the parsing easier.
   # "John Smith, Sr.", is harder than FIRST|LAST|TITLE

   #Now to be sure, there are fancy CSV modules that can
   #handle this complexity, but that does not appear to be
   #the case required here (commas within quotes can mean
   #different than the ones outside of quotes).
   
   my ($name, $city) = (split /\|/, $_)[0,2];
   print "$name",'|',$city,"\n";
}

=prints
NAME|CITY
AAA|STAT
BBB|PPOR
CCC|TRET
=cut

__DATA__
NAME|AGE|CITY|ZIP
AAA|23|STAT|60001
BBB|34|PPOR|12345
CCC|11|TRET|2345
[download]

stevieb:

Yet another version, slightly whackier:

$ cat plonk.pl 
#!/usr/bin/perl
use strict;
use warnings;

my @wanted = qw(CITY NAME);

# get map of column headings (COLNAME=>INDEX)
my %headings = do {
    my $t = <DATA>;
    chomp $t;
    my $cnt=0;
    map { $_=>$cnt++ } split /\|/, $t;
};

while (<DATA>) {
    chomp;
    my @cols = split /\|/;
    # A hash slice to get the column numbers we want, and
    # an array slice to extract those columns from the
    # list....
    print join(", ",@cols[@headings{@wanted}]),"\n";
}

__DATA__
NAME|AGE|CITY|ZIP
AAA|23|STAT|60001
BBB|34|PPOR|12345
CCC|11|TRET|2345

$ perl plonk.pl
STAT, AAA
PPOR, BBB
TRET, CCC
[download]

Update: Improved the (pre-existing) comments a little.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Spreadsheet::Read comes with xlscat, which can filter rows and/or columns from CSV, XLS and other spreadsheet like formats:

$ cat test.csv
NAME|AGE|CITY|ZIP
AAA|23|STAT|60001
BBB|34|PPOR|12345
CCC|11|TRET|2345
$ xlscat --in-sep-char=\| -C1,3 test.csv
NAME|CITY
AAA|STAT
BBB|PPOR
CCC|TRET
$
[download]

For CSV-like formatted files, it uses Text::CSV_XS.

Thank you all for the extremely clear, concise and detailed responses. I even further appreciate the quick adaption to my clarification.

I have much to ponder tomorrow.

Cheers!

Steve